Applescript/Pages and adjusting column width (and paragraph style)

Question

I was hoping that some someone might know how to adjust the width of individual columns in Pages using Applescript. It seems like it should be a simple task, and I can adjust the overall width/height of the table, but I haven't found a way to adjust the column width. Alternatively, I could have the program create the table in Numbers and copy/paste it into Pages, but I'd imagine that would get a bit messy and wouldn't allow me to use a hanging indent in the cells (to the best of my knowledge).
Also, is there a way to adjust the paragraph style used by the text in the table? Otherwise, I could just use a templet and define the the default table style appropriately. (Though not the most elegant solution).
Thanks in advance for your help!
(In case it helps, the script I'm working on parses an unformatted inventory and parses it into paragraphs/tables.)

Answer 1

Try this:
set tableCount to 0
--open file to be pased here, excluded for example
tell application "Pages"
    activate
    set theDoc to (make new document)
    tell theDoc
        --makes paragraph styles used
        make new paragraph style with properties {name:"Folio", font name:"Times New Roman", font size:12, bold:true, alignment:left, space after:5, keep with next paragraph:true, space before:15}
        make new paragraph style with properties {name:"Place", font name:"Times New Roman", font size:12, bold:false, alignment:left, line spacing type:relative, line spacing:100}
        make new paragraph style with properties {name:"Description", font name:"Times New Roman", font size:12, bold:false, italic:true, alignment:left, line spacing type:relative, line spacing:100}
        make new paragraph style with properties {name:"Table", font name:"Times New Roman", font size:12, alignment:left, left indent:0.5, first line indent:0.0}
        --begin repeat, gathers MS info from one doc (unformatted) and writes it into another with formatting, setting variables directly for example
        set MSName to "new Manuscript"
        set MSPlace to "place where MS is stored"
        set MSDesc to "description of MS"
        set tableData to {{"folio", "title", "composer"}, {"", "subtitle", ""}, {"etc", "next", "next"}}
        --write paragraph information from earlier
        set currentPar to (make new paragraph at end of paragraphs with data MSName)
        set paragraph style of currentPar to "Folio"
        set currentPar to (make new paragraph at end of paragraphs with data MSPlace)
        set paragraph style of currentPar to "Place"
        set currentPar to (make new paragraph at end of paragraphs with data MSDesc)
        set paragraph style of currentPar to "Description"
        --create table, add data, and format
        tell application "System Events" to tell process "Pages"
            key code 125 using {command down} -- move the insertion point to the end
            tell menu bar 1
                -- Insert a new table:
                click menu item "Table" of menu 1 of menu bar item "Insert"
                -- Delete the header row:
                tell menu 1 of menu bar item "Format"
                    click menu item "Delete Row" of menu 1 of menu item "Table"
                end tell
                -- Show the Inspector:
                tell menu 1 of menu bar item "View"
                    if menu item "Show Inspector" exists then
                        click menu item "Show Inspector"
                    end if
                end tell
            end tell
            tell window 1 -- the Inspector window
                click radio button 7 of radio group 1 -- select the Table Inspector
                perform action "AXRaise" -- activate the Table Inspector
                tell tab group 1 of group 1
                    click radio button "Table" -- select “Table”
                    -- Reduce width of all three columns:
                    repeat 3 times
                        set value of text field 2 to "0.5 in"
                        set focused of text field 2 to true
                        keystroke return
                        keystroke tab -- next column
                    end repeat
                    key code 126 -- the Up Arrow
                    -- Set width of each column:
                    repeat with theValue in {"0.75 in", "4.25 in", "1.5 in"}
                        set value of text field 2 to theValue
                        set focused of text field 2 to true
                        keystroke return
                        keystroke tab -- next column
                    end repeat
                    key code 126 -- the Up Arrow
                end tell
            end tell
            keystroke "i" using {option down, command down} -- hide the Inspector
            -- Add the data:
            repeat with i from 1 to 3
                set thisRow to item i of tableData
                repeat with j from 1 to 3
                    keystroke (item j of thisRow)
                    if (i * j = 9) then exit repeat
                    keystroke tab
                end repeat
            end repeat
        end tell
        set tableCount to tableCount + 1
        tell table tableCount
            select
            set stroke width to 0.0
            set wrap to center
            set name to MSName
        end tell
        --after which it would continue with the next MS and repeat the process until all are done
    end tell
end tell