AppleScript That Saves Finder Window Size and Location

Question

I wrote the following AppleScript to position and size Finder windows, but the Finder doesn't "remember" the settings the next time I open the windows.
tell application "Finder"
activate
make new Finder window to disk "Hard Drive"
set toolbar visible of Finder window 1 to false
set current view of Finder window 1 to icon view
clean up Finder window 1 by name
set position of Finder window 1 to {30, 55}
set bounds of Finder window 1 to {30, 55, 400, 625}
make new Finder window to folder " Files" of disk "Hard Drive"
set current view of Finder window 1 to icon view
set toolbar visible of Finder window 1 to false
clean up Finder window 1 by name
set position of Finder window 1 to {410, 55}
set bounds of Finder window 1 to {410, 55, 975, 455}
close Finder window 1
close Finder window 1
end tell
How do I make it so the Finder will remember the location and position?

Answer 1

Hello
Here is a script that I use daily.
The code used to force the Finder to "remember" the window position seems a bit tricky. If I remember well I found it on MacScripter.
As far as the Finder is not corrected, we must use this kind of trickery.
--[SCRIPT]
my commun(choose folder)
on open (sel)
my commun(sel's item 1)
end open
(* set bounds to {10, 50, 800, 600} *)
on commun(F)
set F to F as Unicode text
tell application "Finder"
if class of item F is document file then set F to (container of item F) as Unicode text
if ((class of item F) is folder) then my set_bounds(F, {10, 50, 800, 600}, false)
end tell
end commun
on set_bounds(F, b, toolbar)
local ao, i, lesFichiers, fichier
tell application "Finder" to tell folder F
set lesFichiers to every file
repeat with fichier in lesFichiers
my saveImageWithItselfAsIcon(fichier as alias)
end repeat
tell container window
set ao to class is Finder window
open
set current view to icon view
set properties of its icon view options to ¬
{arrangement:arranged by name, icon size:128}
set bounds to b
set toolbar visible to toolbar
set toolbar visible to not toolbar
set toolbar visible to toolbar
if not ao then close
end tell -- to container window
repeat with i in (get folders)
my set_bounds((i as alias), b, toolbar)
end repeat
end tell -- to folder F then to Finder
end set_bounds
on saveImageWithItselfAsIcon(F)
tell application "Image Events"
launch
try
tell (open F)
try
save with icon -- save iconimagefile with itself as icon
end try
close
end tell
end try
end tell
end saveImageWithItselfAsIcon
--[/SCRIPT]
Yvan KOENIG (from FRANCE mardi 13 mars 2007 20:51:14)