Applescript to automate the laboreous matching and moving jpg/CR2 files

Question

Hi
I used to use MS Basic (at school) and was (really) good at Hypertalk but have done no scripting for years (since they killed Hypercard)
I am a photographer (as a hobby) and will take 1000-2000 photos on a weekend. I shoot JPG & CR2. The JPG are much quicker to evaluate and that's why I use them. I will normally keep about 5%. At present I end up manually picking out the CR2 files which match the JPGs I've sorted. This takes up to an hour of horrible, tedious, eye-straining work. I've searched for scripts which would automate this but haven't found one that works ...
I would like a script which would, for instance, get the names of all the JPG files in one folder and find the  (CR2) matches in a second folder and move those (CR2) files to ether a third folder or the folder with the original JPG files are ...
I'm not totally useless at following scripts but also don't know enough Applescript to find out how to make the scripts I've seen which purport to do the job described work ...

Answer 1

This is actually pretty straightforward to do. The following script and its comments should give you an idea.
-- first prompt the user for two folders:
-- 1: the folder of JPEGs to keep
-- 2: the folder of matching CR2 files
set JPEGFolder to (choose folder with prompt "Select the folder of JPEGs to keep:")
set CR2Folder to (choose folder with prompt "Select the folder containing the .CR2 files:")
-- now work your magic
tell application "Finder"
  -- iterate through the JPEGs
  -- the 'whose name extension...' is optional, but will help filter out erroneous files
  repeat with eachFile in (every file of JPEGFolder whose name extension is "jpg") as alias list
  -- work out the base name of the file (i.e. without the '.jpg'
  set basename to (characters 1 through -5 of (get name of file eachFile)) as text
  -- now append ".CR2" to the base name, which gives us the corresponding .CR2 file
  set CR2Filename to basename & ".CR2" as text
  -- now we know the file we're looking for, so copy it
  -- we use a 'try' block to catch any errors (e.g. missing .CR2 files)
  try
  -- this is the line that does the copy
  -- note that it copies the .cr2 to the JPEG folder
  -- change the 'to' parameter to some other folder if you want
  --  the copies to go elsewhere
  duplicate file CR2Filename of CR2Folder to JPEGFolder
  end try
  end repeat
end tell