Applying custom icons to all files of a type

Question

I used to use ResEdit back int he day - and have used various tools on Mac and Windows to change icons. BUt I am stuggling with a default custom icon option for Mac OS X.
I have a set of farily simply icons for use with a number of file types that I use a lot - csv, psl, pti, tp3, xml, cfr, and others and I would like to always have newly created files get the custom icon.
Ideally this would be based on the extension - and they are not all from the same app.
I am not afraid to use the terminal or edit package contents. Although some of them are windows apps - and I already have a custom set in the virtual machine.
Some of the solutions I have seen out there such as Candy Bar seem to be only for application and folder settings.
In a couple cases - such as the .cfr and .pti - the apps do not have an open method where you can double click on the file and have it open - so I woudl be okay with something like reprogramming TextEdit to have the necessary icons and plist updates. Although when I tried to edit the plist file in TextEdit - all I did was render TextEdit unusable.
any help in the right direction will be appreaciated - I find it very helpful when I create 30 to 40 files ( a group of 5 differnet file types for each option ) to have icons that help me determine which ones I need to run a macro against - and which to send the customer - and which to upload to the vendor - etc.
Also missing the colorful icons in the sidebar and iTunes - as well an Unsanity Haxies - guess what audio feedback does make me more productive or at the very least more certain that the system is behaving as I expect.

Answer 1

A new Cocoa-AppleScript application can be created from the AppleScript Editor > File > New from Template > Cocoa-AppleScript Applet menu item, pasting in the following script:
-- set icon
on run -- application double-clicked
    tell current application's NSOpenPanel's openPanel()
        setFloatingPanel_(true)
        setTitle_("Choose file items to set an icon for:")
        setPrompt_("Choose") -- the button name
        setDirectoryURL_(current application's NSURL's URLWithString_(POSIX path of (path to desktop)))
        setCanChooseFiles_(true)
        setCanChooseDirectories_(false)
        setShowsHiddenFiles_(false)
        setTreatsFilePackagesAsDirectories_(false)
        setAllowsMultipleSelection_(true)
        set theResult to runModal() as integer
        if theResult is current application's NSFileHandlingPanelCancelButton then tell me to quit -- cancel button
        set theFiles to URLs() as list
    end tell
    repeat with eachFile in theFiles -- coerce the file paths in place
        tell eachFile to set its contents to its |path|() as text
    end repeat
    open theFiles
end run
on open theItems -- items dropped onto the application
    try -- get a path to the image to be used for the icon
        set imageFile to POSIX path of (choose file with prompt "Select an image file for the icon:" of type "public.image")
    on error -- cancel button
        tell me to quit
    end try
    set errorList to {} -- this will be a list of problem files, if any
    repeat with eachItem in theItems
        if not setIcon(imageFile, eachItem) then
            set end of errorList to (eachItem & return)
        end if
    end repeat
    if errorList is not {} then -- oops, show items where there was a problem
        display alert "Error setting icon." message "Icons of the following items were not set:" & return & return & errorList as text
    end if
    tell me to quit -- done
end open
to setIcon(imageFilePath, fileItemPath) -- set the icon of a file item
    set mySharedWorkspace to current application's NSWorkspace's sharedWorkspace()
    set myImage to current application's NSImage's alloc's initWithContentsOfFile_(imageFilePath)
    try
        return mySharedWorkspace's setIcon_forFile_options_(myImage, fileItemPath, 0) as boolean
    on error errorMessage
        return false
    end try
end setIcon
After saving, the resulting application can be double-clicked, or you can drop files onto it (the script can't be run from the script editor).  It can be tweaked further to include image files in the application bundle to select from (the icon images can be any image, not just icon files), or to be used in the Finder's toolbar, but for now the basic application should get you started.