Array in Forms

Question

Hi all
What is the problem in this code
declare
type temp is record (invoice_num inv_detail.invoice_num%type);
type temp5 is table of temp index by binary_integer;
temp6 temp5;
idx integer := 0;
begin
     go_block('inv_search');
     first_record;
     loop
     temp6(idx) := :inv_search.inv_code;
     next_record;
     idx := idx + 1;
     exit when :system.last_record = 'TRUE' ;
     end loop;
     temp6(idx) := :inv_search.inv_code;
end;
compile error "expression is wrong type"
Thanks
Selvam

Answer 1

temp6 is a array of RECORDS. You cannot move a single item value to a record. It will work if you change both lines where you say  temp6(idx) := :inv_search.inv_code;to  temp6(idx).invoice_num := :inv_search.inv_code;However, there is no need to create a record with a single column in it. You could more easily create an array of just the single column. I have changed your code around to illustrate, and changed the order of steps here:
declare
  type invoice_num_TblTyp is table of inv_detail.invoice_num%type
                             index by binary_integer;
  invoice_num_Tbl invoice_num_TblTyp;
  idx integer;
begin
  go_block('inv_search');
  first_record;
  invoice_num_Tbl.delete;
  loop
    exit when :system.record_status = 'NEW';
    idx := :system.cursor_record;
    invoice_num_Tbl(idx) := :inv_search.inv_code;
    exit when :system.last_record = 'TRUE' ;
    next_record;
  end loop;
  first_record;
  Message('Invoice_Num_Tbl contains '
           ||nvl(invoice_num_Tbl.Last,0)||' records.');
end;