Array in procedure

Question

Hi,
I have a procedure that will be receiving TEMPLATE_ID's has input parameter in a procedure. Now there can be more than one template Id passed into the procedure. What is the best way to handle this situation? Can I create some sort of array for an IN parameter in the procedure?
Please Advise,
Marc.

Answer 1

Like you would any other type except you define the type yourself...
Nested Table Type (some people call this "schema-level type" because you create it at the schema level using CREATE TYPE...):
CREATE TYPE collection_type AS TABLE OF VARCHAR2(4000);
CREATE PROCEDURE example_procedure( p_array IN collection_type ) IS
   i PLS_INTEGER;
BEGIN
   i := p_array.FIRST;
   WHILE i IS NOT NULL LOOP
      DBMS_OUTPUT.PUT_LINE(p_array(i));
      i := p_array.NEXT(i);
   END LOOP;
END;
BEGIN
   example_procedure( collection_type( 'APPLE', 'ORANGE', 'TOASTER OVEN' ) );
END;
Packaged Associative Array Type (either in a dedicated package or as part of your actual package)
CREATE PACKAGE example_package AS
   TYPE array_type IS TABLE OF VARCHAR2(32767)
      INDEX BY PLS_INTEGER;
   PROCEDURE procedure_name( p_array IN example_package.array_type );
END example_package;
/You can do the package body yourself, but here's an example of calling it...
DECLARE
   v_array example_package.array_type;
BEGIN
   v_array(1) := 'APPLE';
   v_array(2) := 'ORANGE';
   v_array(3) := 'TOASTER OVEN';
   example_package.procedure_name(p_array => v_array);
END;
Packaged Nested Table Type
CREATE PACKAGE example_package AS
   TYPE array_type IS TABLE OF VARCHAR2(32767);
   PROCEDURE procedure_name( p_array IN example_package.array_type );
END example_package;
/You can do the package body yourself, but here's an example of calling it...
DECLARE
   v_array example_package.array_type := example_package.array_type('APPLE', 'ORANGE', 'TOASTER OVEN');
BEGIN
   example_package.procedure_name(p_array => v_array);
END;
/All typed freehand so there might be some syntax typos...
Regards