Assistance Needed With Creating a Dynamic Query

Question

I am attempting to rename several of my primary key/foreign key constraints from the default "SYS" names to something actually meaningful. I have several "semi-dynamic" queries that look something like this:
SELECT 'ALTER TABLE L_ROLE RENAME CONSTRAINT ' || CONSTRAINT_NAME || ' TO NN_ROLE_ID; ' FROM USER_CONSTRAINTS WHERE CONSTRAINT_TYPE ='C' AND TABLE_NAME='L_ROLE' AND search_cond(constraint_name)='"ID" IS NOT NULL';
Unfortunately, I have to capture the output of this script and run THOSE statements to get anything done.
I would like to convert this to simply use EXECUTE IMMEDIATE or if necessary a stored procedure. Unfortunately, I'm a bit confused on what the end result would look like. Any assistance would be appreciated.
Jason
p.s."search_cond" is a custom function defined as follows:
create function search_cond( p_cons_name in varchar2 ) return varchar2
as
l_search_condition varchar2(4000);
begin
     select SEARCH_CONDITION into l_search_condition
     from user_constraints
     where constraint_name = p_cons_name;
return l_search_condition;
end;
For some reason, just running the query outside the function doesn't work.

Answer 1

OK, try this. Please note that I commented out the actual exec immediate line and instead just dbms_output the commands that will get executed. This way you can try this first to make sure it produces what you expect. Then just put the exec immediate back in when you are ready.
DECLARE
    TYPE cur_typ IS REF CURSOR;
    v_cursor cur_typ;
    v_query VARCHAR2(1000);
    v_exec VARCHAR2(1000);
BEGIN
    v_query := 'SELECT ''ALTER TABLE ''||uc.table_name||''  RENAME CONSTRAINT '' || uc.constraint_name ||
                      '' TO NN_''||ucc.column_name||'' '' thequery
                FROM  user_constraints uc,
                      user_cons_columns ucc
                WHERE uc.constraint_name = ucc.constraint_name
                AND   uc.constraint_type =''C''
                AND   search_cond(uc.constraint_name)=''"ID" IS NOT NULL''
                AND   uc.constraint_name LIKE ''SYS%'' ';
    DBMS_OUTPUT.PUT_LINE(v_query);
    OPEN v_cursor FOR v_query;
    LOOP
        FETCH v_cursor INTO v_exec;
        EXIT WHEN v_cursor%NOTFOUND;
        --EXECUTE IMMEDIATE (v_exec);
        dbms_output.put_line(v_exec);
    END LOOP;
    CLOSE v_cursor;   
END;
/Greg