Bakcground Job Creation

Question

Hello everybody,
I have the next requirement, I need an option in the menu in a Z dynpro program to execute the transaction in a background job, the problem is that i need it to work just like this option works with selection screens, that in the Program option in the menu it has the Execute in background, so it generates automatically the job, I've seen the functions JOB_OPEN, JOB_SUBMIT and JOB_CLOSE they will work the problem is with the variant cause there is no variants and i don't know how the system generates some kind of temporal variant with a name such as &00000000054 and so on, does anyone know how can i do this, thanks in advance.
Regards,
Julio Cesar

Answer 1

You don't need a temporary variant for this.  Just use the SUBMIT statement and pass your data(captured in the screen) to another "Z" program using the WITH statement.  Problemm solved.
data:   l_valid,
        ls_params like pri_params,
        l_jobcount like tbtcjob-jobcount,
        l_jobname  like tbtcjob-jobname.
* Get Print Parameters
  call function 'GET_PRINT_PARAMETERS'
       exporting
            no_dialog      = 'X'
       importing
            valid          = l_valid
            out_parameters = ls_params.
* Open Job
  l_jobname = 'Z_SUBMITTED_PROGRAM'.
  call function 'JOB_OPEN'
       exporting
            jobname  = l_jobname
       importing
            jobcount = l_jobcount.
* Submit report to job
  submit z_submitted_program
       with P_parm1 = <some_value>
       with P_parm2 = <some_value>
       via job     l_jobname
           number  l_jobcount
       to sap-spool without spool dynpro
           spool parameters ls_params
              and return.
* Schedule and close job.
  call function 'JOB_CLOSE'
       exporting
            jobcount  = l_jobcount
            jobname   = l_jobname
            strtimmed = 'X'.
Regards.
Rich Heilman
Edited by: Rich Heilman on May 21, 2008 3:51 PM