Bash script to replace markers in file

Question

Hi,
I have a file of the form (testfile.txt):
here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here
$file1.txt$
Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more $file2.txt$
Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here Some text in here and more here
$file3.txt$
I also have text files with names of the form "filen.txt" which have Markdown tables in them.
age   weight   sex 
15    45       m   
20    56       f   
25    65       f   
30    72       m   
I want to run a script to search for all the markers, and "inject" the relevant table at the marker by opening the file of that name in the same directory and doing a replace with it.
I have the "shell" of the script (sorry about the pun). I cannot however get it to do the injecting part.
I've tried Awk, sed, perl....you name it.
The script so far is:
#!/bin/bash
line=""
places=""
while read -r line; do
    places=$(awk '/\$*\$/ { print $0 }')
done < testfile.txt
cp testfile.txt try.txt
echo "$places" | {
    while read line; do
        strip=$(echo $line | sed 's/^\$//')
        strip=$(echo $strip | sed 's/\$$//')
        curtext=$(cat $strip)
         cat try.txt | {
            while read line; do
            # Something in here to take $strip add a $ at each end and replace
            #+with $curtext
            done
    done
I would really appreciate some help to fill in the area where the comment is. I am successfully getting all the other bits to work.
Many thanks
Mike

Answer 1

sed gives me a headache.  It has its place in the world, but I would never use it unless I had no other option. You do. Here's the same thing in AppleScript:
-- set main paths
set master_file to "/path/to/master file.txt"
set main_folder to "/path/to/folder/"
-- read master text, and break it down around '$' marks
set master_text to read master_file
set text_chunks to tid({input:master_text, delim:"$"})
-- loop through chunks, replacing file names with file contents
repeat with this_chunk in text_chunks
          if this_chunk ends with ".txt" then
                    set contents of this_chunk to (read (main_folder & this_chunk))
          end if
end repeat
-- write it all back out to the master file
set fp to open for access master_file with write permission
write tid({input:text_chunks, delim:""}) to fp
close access fp
on tid({input:input, delim:delim})
  -- generic handler for text delimiters
          set {oldTID, my text item delimiters} to {my text item delimiters, delim}
          if class of input is list then
                    set output to input as text
          else
                    set output to text items of input
          end if
          set my text item delimiters to oldTID
          return output
end tid
A bit wordier, but so much easier on the brain.