Batch jobs and deleting one time variants

Question

Hi,
I have a need to generate a background job with up to
21 steps each step needing a different variant determined
at creation.
I have written an abap that will create the job, steps
and variants for the batch stream. This works fine.
  My problem is trying to delete the variants I created
  at the end of the batch stream. I have tried setting
  up another step to delete the variant but that fails
  as RS_DELETE_VARIANT gives an error if the variant
  exists in a current batch job, which it does in this
  case as the variants are used in previous steps.
  Ideally I would like to create variants as SAP itself
  does when you dynamically submit a job to batch.
  How can I get around this problem elegantly ?
Allan

Answer 1

Dear Allan
  Welcome to SDN.
  One solution that i can propose is:
  With the ABAP Program that submits the job, do the following:
  Step 1: Open the job using FM: JOB_OPEN.
  Step 2: Submit all programs using SUBMIT statements and values for parameter with reference to the job-id and job counter.( I guess if we use JOB_SUBMIT here we will be specifying the variant name which already exists).
  Step 3: Close the job using FM: JOB_CLOSE.
  Using the above procedure the variants created will be temporary and no need to delete.
Below is an example which can help you understand the same:
PERFORM JOB_OPEN USING SY-REPID CHANGING L_JOBCNT.
SUBMIT Y00_SD_F2_003 WITH P_BUKRS = P_BUKRS
                     WITH P_FILE1 = P_OFILE
                     WITH P_RUN = P_RUN
                     VIA JOB SY-REPID NUMBER L_JOBCNT
                     TO SAP-SPOOL WITHOUT SPOOL DYNPRO
                     WITH DESTINATION = 'HPMISPRT'
                     WITH IMMEDIATELY = SPACE
                     WITH KEEP_IN_SPOOL = 'X'
                     AND RETURN.
PERFORM JOB_CLOSE USING L_JOBCNT SY-REPID.
*&      Form  JOB_OPEN
FORM JOB_OPEN  USING    P_REPID
               CHANGING P_JOBCNT LIKE TBTCJOB-JOBCOUNT.
DATA: L_REPID  LIKE TBTCJOB-JOBNAME.
   L_REPID = SY-REPID.
   CALL FUNCTION 'JOB_OPEN'
     EXPORTING
       JOBNAME                = L_REPID
    IMPORTING
      JOBCOUNT               = P_JOBCNT
    EXCEPTIONS
      CANT_CREATE_JOB        = 1
      INVALID_JOB_DATA       = 2
      JOBNAME_MISSING        = 3
      OTHERS                 = 4.
   IF SY-SUBRC <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
   ENDIF.
ENDFORM.                    " JOB_OPEN
*&      Form  JOB_CLOSE
FORM JOB_CLOSE  USING    P_JOBCNT LIKE TBTCJOB-JOBCOUNT
                         P_REPID.
DATA: L_RELEASE(1) TYPE c,           "Job released
      L_REPID  LIKE TBTCJOB-JOBNAME.
   L_REPID = SY-REPID.
   CALL FUNCTION 'JOB_CLOSE'
     EXPORTING
       JOBCOUNT                          = P_JOBCNT
       JOBNAME                           = L_REPID
       STRTIMMED                         = 'X'
    IMPORTING
      JOB_WAS_RELEASED                  = L_RELEASE
    EXCEPTIONS
      CANT_START_IMMEDIATE              = 1
      INVALID_STARTDATE                 = 2
      JOBNAME_MISSING                   = 3
      JOB_CLOSE_FAILED                  = 4
      JOB_NOSTEPS                       = 5
      JOB_NOTEX                         = 6
      LOCK_FAILED                       = 7
      INVALID_TARGET                    = 8
      OTHERS                            = 9.
   IF SY-SUBRC <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
   ENDIF.
ENDFORM.                    " JOB_CLOSE
   Hope the above info lead you in solving your problem.
Kind Regards
Eswar