BDC Calling MIGO transaction with different actions

Question

Hi everyone,
i am doing a  BDC for MIGO t-code....to create Good Receipt w.r.t Purchase Order.....
While executing the Pgm....if some other user has opened the MIGO t-code in DISPLAY mode then that pgm is not able to call the MIGO t-code...to create Good Receipt w.r.t Purchase Order.....
As this  bdc pgm is witten to create the good receipt i.e. why it is not allowing to create the receipt as already someone else has opened it in DISPLAY mode....
The following code is to create Good Receipt w.r.t Purchase Order.....
  perform bdc_field       using 'GODYNPRO-ACTION'
                                'A01'. -
Good receipt
  perform bdc_field       using 'GODYNPRO-REFDOC'
                                'R01'.-----Purchase order
PLease if somebody can help me out with this code...or can send me any program related to this pgm.
With Regards,
Seevangi Mishra

Answer 1

Try using the bapi BAPI_GOODSMVT_CREATE.
Here is part of the code:
method create_goodsreceipt.
  data: ls_header   type bapi2017_gm_head_01.
  data: lv_code     type bapi2017_gm_code.
  data: lv_document type bapi2017_gm_head_ret-mat_doc.
  data: lv_year     type bapi2017_gm_head_ret-doc_year.
  field-symbols: <fsi>  type bapi2017_gm_item_create.
  data: lt_items type bapi2017_gm_item_create_t.
  data: lt_ret type table of bapiret2.
  data: ls_ret type bapiret2.
  data: lv_error type xfeld.
  data: ls_headout type bapi2017_gm_head_ret.
  lt_items[] = items[].
* header position
  ls_header-pstng_date = sy-datum.
  ls_header-doc_date = sy-datum.
  ls_header-ref_doc_no = 'ref do no'.
  ls_header-pr_uname = sy-uname.
  ls_header-header_txt = 'header test'.
* code invullen
  move '01' to lv_code.
* aanpassen items table
  loop at lt_items assigning <fsi>.
    <fsi>-move_type = '101'.
    <fsi>-mvt_ind = 'B'.
    <fsi>-po_number = me->ebeln.
    <fsi>-plant = me->bukrs.
  endloop.
* bapi oproepen
  call function 'BAPI_GOODSMVT_CREATE'
    exporting
      goodsmvt_header  = ls_header
      goodsmvt_code    = lv_code
      testrun          = testrun
    importing
      goodsmvt_headret = ls_headout
      materialdocument = lv_document
      matdocumentyear  = lv_year
    tables
      goodsmvt_item    = lt_items
      return           = lt_ret.
* commit
  if testrun = space .
    lv_error = zcl_bapi=>check_for_errors( lt_ret ).
    if lv_error is initial.
      ls_ret-type = 'S'.
      ls_ret-id = 'CREATED'.
      ls_ret-message = ls_headout.
      ls_ret-message_v1 = ls_headout-mat_doc.
      append ls_ret to lt_ret.
      call function 'BAPI_TRANSACTION_COMMIT'.
    endif.
  endif.
  returntable[] = lt_ret[].
endmethod.
Hope it helps you,
Bert