Binding a variable

Question

Hi all,
How can we bind a variable if the column name exists in another
table.
For ex.
I have two tables lets say tab1,tab2. The tab2 holds the
column names of tab1.
table structure and data is.
tab1
id col1 col2 col3 col4
1 234 sysdate 3233 334.93
2 235 sydate 345 33.42
tab2
id inv_no date vendor
1 col1 col2 col4
2 col3 col4 col5
based on these two table values, I have to build a variable.
ex.
l_var = 234 ||sysdate||334.93;
And every time in my table 1, I will have at least 50 to 70k
rows. How can i do this. Please help me any one.
Thanks,
Swetha.

Answer 1

Try opening a ref cursor dynamically like this:
SQL> EDIT file_name
CREATE OR REPLACE PACKAGE package_name
AS
  TYPE cursor_type IS REF cursor;
  PROCEDURE procedure_name;
END package_name;
CREATE OR REPLACE PACKAGE BODY package_name
AS
  PROCEDURE procedure_name
  IS
    cursor_name package_name.cursor_type;
    CURSOR c_tab2 IS SELECT * FROM tab2;
    v_inv_no VARCHAR2 (30)    := NULL;
    v_date   VARCHAR2 (30)    := NULL;
    v_vendor VARCHAR2 (30)    := NULL;
    v_sql    VARCHAR2 (4000)  := NULL;
    l_inv_no VARCHAR2 (1000)  := NULL; 
    l_date   VARCHAR2 (1000)  := NULL; 
    l_vendor VARCHAR2 (1000)  := NULL; 
    l_var    VARCHAR2 (2000)  := NULL;
  BEGIN
    FOR r_tab2 IN c_tab2
    LOOP
      v_inv_no := r_tab2.inv_no;
      v_date   := r_tab2.date_col;
      v_vendor := r_tab2.vendor;
      v_sql    := 'SELECT ' || v_inv_no || ','
                            || v_date   || ','
                            || v_vendor
              || ' FROM tab1 WHERE id = :n';
      OPEN cursor_name FOR v_sql USING r_tab2.id;
      LOOP
        FETCH cursor_name INTO l_inv_no, l_date, l_vendor;
        EXIT WHEN cursor_name%NOTFOUND;
        l_var    := r_tab2.id || ' '
                 || l_inv_no  || ' '
                 || l_date    || ' '
                 || l_vendor;
        DBMS_OUTPUT.PUT_LINE (l_var);
      END LOOP;
    END LOOP;
  END procedure_name;
END package_name;
SQL> START file_name
Package created.
Package body created.
SQL> SET SERVEROUTPUT ON
SQL> EXEC package_name.procedure_name
1 234 26-OCT-01 334.93
2 345 33.42
2 346 35
PL/SQL procedure successfully completed.