Can't delete a file displayed in ListView ("File in use") even after removing it from window.

Question

I have a ListView displaying a collection of icons. The user can then select different icons (checkboxes) to do things like Copy or Delete.
Problem is, when I try to delete the actual file from the disk, I get an error telling me the file is "in use" ("vshost.exe", the VS runtime during testing).
I thought maybe it was because it still appeared in the window and was still in the ImageList, but even after removing it from both locations, I still get the error. My code:
Dim intCnt As Integer = 0
Do
ImageList2.Images.RemoveAt(intIconsChecked(intCnt)) ' Remove from collection.
lsvCollection.Items.RemoveAt(intIconsChecked(intCnt)) ' Remove from ListView window.
FileIO.FileSystem.DeleteFile(strIconPath & "\Icon" & Format(intCnt + 1, "00") & ".rsc") ' "+1" b/c Icons start with "01".
FileIO.FileSystem.DeleteFile(strIconPath & "\Icon" & Format(intCnt + 1, "00") & ".png") ' "In use" Error here.
".rsc" deletes just fine, so I know I'm deleting the correct file. Why does VS still think the file is still "in use"?
Thx

Answer 1

Mugsy,
Consider this as food for thought, even if you don't use it.
If you set it up right then you can control how it works. A reference is a reference and any left behind will cause you grief down the road when you try to delete things.
As an example, a simple class follows. It does *not* implement IDispose, although it does have a private shared Dispose method in it:
Public Class MyImages
Private _bmp As Bitmap
Private _name As String
Private _sourceFilePath As String
Private Sub New(ByVal bmp As Bitmap, _
ByVal name As String, _
ByVal filePath As String)
_bmp = bmp
_sourceFilePath = filePath.Trim
_name = name.Trim
End Sub
Public ReadOnly Property Bmp As Bitmap
Get
Return _bmp
End Get
End Property
Public ReadOnly Property Name As String
Get
Return _name
End Get
End Property
Public ReadOnly Property SourceFilePath As String
Get
Return _sourceFilePath
End Get
End Property
Public Shared Sub AddNew(ByRef miList As List(Of MyImages), _
ByVal imageFilePath As String)
Try
If miList Is Nothing Then
Throw New ArgumentNullException("The collection of MyImages cannot be null.")
ElseIf String.IsNullOrEmpty(imageFilePath) OrElse imageFilePath.Trim = "" Then
Throw New ArgumentException("The file path of the image cannot be null or empty.")
ElseIf Not My.Computer.FileSystem.FileExists(imageFilePath) Then
Throw New IO.FileNotFoundException("The file path of the image could not be located.")
Else
' Should do validation here that the file
' is actually an image but I'll not do this
' here...
Dim thisBMP As Bitmap = New Bitmap(imageFilePath)
miList.Add(New MyImages(thisBMP, GetFileNameWithoutExtension(imageFilePath), imageFilePath))
End If
Catch ex As Exception
Throw
End Try
End Sub
Public Shared Sub AddNew(ByRef miList As List(Of MyImages), _
ByVal imageFilePath As String, _
ByVal imageName As String)
Try
If miList Is Nothing Then
Throw New ArgumentNullException("The collection of MyImages cannot be null.")
ElseIf String.IsNullOrEmpty(imageFilePath) OrElse imageFilePath.Trim = "" Then
Throw New ArgumentException("The file path of the image cannot be null or empty.")
ElseIf Not My.Computer.FileSystem.FileExists(imageFilePath) Then
Throw New IO.FileNotFoundException("The file path of the image could not be located.")
ElseIf String.IsNullOrEmpty(imageName) OrElse imageName.Trim = "" Then
Throw New ArgumentException("The name of this image cannot be null or empty.")
Else
' Should do validation here that the file
' is actually an image but I'll not do this
' here...
Dim thisBMP As Bitmap = New Bitmap(imageFilePath)
miList.Add(New MyImages(thisBMP, imageName, imageFilePath))
End If
Catch ex As Exception
Throw
End Try
End Sub
Public Shared Sub Remove(ByRef miList As List(Of MyImages), _
ByVal imageFilePath As String, _
Optional ByVal removeFilePathAlso As Boolean = False)
Try
If miList Is Nothing Then
Throw New ArgumentNullException("The collection of MyImages cannot be null.")
ElseIf String.IsNullOrEmpty(imageFilePath) OrElse imageFilePath.Trim = "" Then
Throw New ArgumentException("The file path of the image cannot be null or empty.")
ElseIf Not My.Computer.FileSystem.FileExists(imageFilePath) Then
Throw New IO.FileNotFoundException("The file path of the image could not be located.")
Else
Dim findInstance As System.Collections.Generic.IEnumerable(Of MyImages) = _
From mi As MyImages In miList _
Where mi.SourceFilePath = imageFilePath
If findInstance.Count <> 1 Then
Throw New ArgumentException("The instance of MyImages specified by the" & vbCrLf & _
"image file path is not in the collection.")
Else
Dispose(findInstance.First)
If removeFilePathAlso Then
My.Computer.FileSystem.DeleteFile(findInstance.First.SourceFilePath)
End If
miList.Remove(findInstance.First)
End If
End If
Catch ex As Exception
Throw
End Try
End Sub
Private Shared Sub Dispose(ByVal instance As MyImages)
If instance IsNot Nothing AndAlso instance._bmp IsNot Nothing Then
instance._bmp.Dispose()
instance._bmp = Nothing
End If
End Sub
End Class
When you look through that, look specifically at the "Remove" method and in particular, look at the order in which things are done. That's the critical part in this.
I tested it with a simple form:
Two buttons, a checkbox, and a picturebox. I also copied a small folder full of image files to my desktop since I'll be deleting a file from it. Following is the code for Form1:
Option Strict On
Option Explicit On
Option Infer Off
Imports System.IO.Path
Public Class Form1
Private miList As New List(Of MyImages)
Private Sub Form1_Load(ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles MyBase.Load
Dim desktop As String = _
My.Computer.FileSystem.SpecialDirectories.Desktop
Dim imgFolder As String = _
Combine(desktop, "Images")
PictureBox1.BorderStyle = BorderStyle.FixedSingle
For Each imgFilePath As String In My.Computer.FileSystem.GetFiles(imgFolder)
MyImages.AddNew(miList, imgFilePath)
Next
btn_RemoveFirstImage.Enabled = False
CheckBox_RemoveSourcePath.Enabled = False
End Sub
Private Sub btn_ShowFirstImage_Click(sender As System.Object, _
e As System.EventArgs) _
Handles btn_ShowFirstImage.Click
Try
If miList.Count >= 1 Then
With PictureBox1
.SizeMode = PictureBoxSizeMode.Zoom
.Image = miList(0).Bmp
End With
btn_RemoveFirstImage.Enabled = True
CheckBox_RemoveSourcePath.Enabled = True
End If
Catch ex As Exception
MessageBox.Show(String.Format("An exception was thrown:{0}{0}{1}", vbCrLf, ex.Message), _
"Exception", MessageBoxButtons.OK, MessageBoxIcon.Warning)
End Try
End Sub
Private Sub btn_RemoveFirstImage_Click(sender As System.Object, _
e As System.EventArgs) _
Handles btn_RemoveFirstImage.Click
Try
If miList.Count >= 1 Then
MyImages.Remove(miList, miList(0).SourceFilePath, CheckBox_RemoveSourcePath.Checked)
End If
PictureBox1.Image = Nothing
btn_RemoveFirstImage.Enabled = True
CheckBox_RemoveSourcePath.Enabled = True
Catch ex As Exception
MessageBox.Show(String.Format("An exception was thrown:{0}{0}{1}", vbCrLf, ex.Message), _
"Exception", MessageBoxButtons.OK, MessageBoxIcon.Warning)
End Try
End Sub
End Class
Running it is straightforward:
Now when I click to show the first one:
A different image is shown because that first one no longer exists - either in the collection or in the folder.
Closing/disposing all references is the key and the order matters.
Something to consider the next time around. :)
Still lost in code, just at a little higher level.