Can't find file in new folder?

Question

I'm writing a script that exports some data from Excel then opens the file in TextWrangler to do a find & replace. The first part of the script checks to see if there's a Folder called "Output" on the desktop, if not create the folder.
If I run the script and the "output" isn't on the desktop it does create folder but the script errors with: "Can't make <class cfol> "Output" of <class cfol> "Desktop" of <class cfol> "user" of <class cfol> "Users" of <class sdsk> od application "Finder" into type list, record or text.
But if I run the script with the "Output" folder already created it runs as expected.
Any ideas??
Here's my code:
set OutputFolder to "Output"
--set DefaultFolder to (path to documents folder as string) & "My Stuff:User Lists:" as alias
(* Keep exported CSV file? *)
set deleteCSV to true
set targetFolder to (path to desktop folder) & OutputFolder & ":" as string
try
get targetFolder as alias
on error
tell application "Finder"
activate
set targetFolder to make new folder at (path to desktop folder) with properties {name:OutputFolder}
end tell
end try
(* Select Users to Export *)
set ExcelDocument to choose file with prompt "Please choose User List." without invisibles
(* Open Users in Excel *)
tell application "Microsoft Excel"
open ExcelDocument
activate object sheet "PC Information"
set f_path to targetFolder as string
--get sheet name
set Nameofsheet to name of active workbook
-- remove file extension
set Nameofsheet to name of active workbook
if text -4 of Nameofsheet is "." then
set Nameofsheet to (text 1 thru -5 of Nameofsheet)
end if
-- save with new file name as CSV type
save active workbook in f_path & Nameofsheet & " PC" & ".csv" as CSV
-- close the sheet
set CloseSheet to active workbook
set saved of CloseSheet to true
close active workbook
end tell
(* Find and Replace *)
set file3 to alias f_path & Nameofsheet & " PC" & ".csv" as string
tell application "TextWrangler"
open {file file3} with LF translation
replace "\\t" using "," searching in text 1 of text document 1 options {search mode:grep, starting at top:false, wrap around:false, backwards:false, case sensitive:false, match words:false, extend selection:false}
replace "\"" using "" searching in text 1 of text document 1 options {search mode:grep, starting at top:false, wrap around:false, backwards:false, case sensitive:false, match words:false, extend selection:false}
set properties of text window 1 to {show invisibles:true}
set properties of text document 1 to {line breaks:DOS}
--save text document 1
save text document 1 to targetFolder & Nameofsheet & " PC" & ".txt"
close document 1
end tell
(* Delete CSV file? *)
if deleteCSV is true then
do shell script ("rm " & (quoted form of POSIX path of file3))
end if
(* End *)
tell application "Finder"
activate
display dialog "The Group " & Nameofsheet & " has been exported."
end tell
eMac 1.25GHz (Tiger) & G5 Xserve (Tiger)   Mac OS X (10.4.5)  

Answer 1

Hi Ben
In the case when your script creates a new folder, you're changing the variable targetFolder from a path (as string) to a Finder item. Excel needs the path.
set targetFolder to (path to desktop folder) & outputfolder
-- targetfolder is a string at this point
--snip
--the alias targetfolder doesn't exist, so:
tell app "Finder" to set targetfolder to make new folder at desktop with properties {name:outputfolder} -- targetfolder is now a Finder object, not a string or an alias
-- snip
-- a bit later:
tell app "Excel" to do things to targetFolder
--Excel doesn't speak Finder, you get the error.
As far as I can see you don't need to use the variable targetFolder for anything other than the string, so all you should need to do is:
tell application "Finder" to make new folder at desktop with properties {name:outputfolder}
The variable targetFolder doesn't get changed, and Excel will still understand it.
Hope this helps,
H