Can you input records to a COLLECTION TYPE object and use it as a table??

Question

My PL/SQL stored procedure creates a list of employee number and phone number records. I don't want to store them in a table. I will be passing this list from one procedure to another in my package.
I created the object type (record) and collection type (table) using this statements.
CREATE TYPE obj_emp_phone_rec AS OBJECT
     emp_number   NUMBER,
     emp_phone    VARCHAR2(100)
CREATE TYPE obj_emp_phone_recs_table AS TABLE OF obj_emp_phone_rec
/Thing is, can I use the obj_emp_phone_recs_table "table type" as a table?
I.e. can I insert records to this in the package procedure and pass reference to it in called sub-procedures.
i.e. something like this
PACKAGE BODY abc IS
  PROCEDURE kdkddk IS
  BEGIN
    -- Insert records to the  obj_emp_phone_recs_table
    obj_emp_phone_recs_table(1).emp_number := '1';
    obj_emp_phone_recs_table(1).emp_phone   := '0774949494';
    obj_emp_phone_recs_table(2).emp_number := '234';
    obj_emp_phone_recs_table(2).emp_phone   := '285494';
    -- Pass the table to the sub procedure
    xyx(obj_emp_phone_recs_table);
  END kdkddk;
END abc;If so how to insert to the obj_emp_phone_recs_table ???
Nothing on the net. In the Net I found only where u define a normal table's column as an object type and then inserting records to it.
Any help would be greatly appreciated.
Edited by: user12240205 on Oct 6, 2011 2:08 AM

Answer 1

mhouri > drop type obj_emp_phone_recs_table;
Type dropped.
mhouri > drop type obj_emp_phone_rec ;
Type dropped.
mhouri > CREATE TYPE obj_emp_phone_rec AS OBJECT
  2    (
  3       emp_number   NUMBER,
  4       emp_phone    VARCHAR2(100)
  5    )
  6  /
Type created.
mhouri > CREATE TYPE obj_emp_phone_recs_table AS TABLE OF obj_emp_phone_rec
  2  /
Type created.
mhouri > create or replace procedure p1(pin_tab IN obj_emp_phone_recs_table)
  2  is
  3   begin
  4     for j in 1..pin_tab.count
  5     loop
  6      dbms_output.put_line('record number '||j ||'-- emp number --'||pin_tab(j).emp_number);
  7     end loop;
  8 
  9  end p1;
10  /
Procedure created.
mhouri > create or replace procedure p2
  2  is
  3  lin_tab  obj_emp_phone_recs_table := obj_emp_phone_recs_table();
  4  begin
  5  FOR i IN 1 .. 5
  6     LOOP
  7        lin_tab.extend;
  8        lin_tab(i) := obj_emp_phone_rec(i, 'i-i-i');
  9     END LOOP;
10 
11    p1(lin_tab);
12 
13  end p2;
14  /
Procedure created.
mhouri > set serveroutput on
mhouri > exec p2
record number 1-- emp number -- 1                                                                                                                                                                                                                         
record number 2-- emp number --2                                                                                                                                                                                                                         
record number 3-- emp number --3                                                                                                                                                                                                                         
record number 4-- emp number --4                                                                                                                                                                                                                         
record number 5-- emp number --5                                                                                                                                                                                                                         
PL/SQL procedure successfully completed.Best Regards
Mohamed Houri