Can you tell me how to execute the procedure?

Question

create or replace get_dob
(ss_number varchar2,dob out date)
as
begin
select birth_dae
into dob
from person
where soc_sec_num=ss_num;
exception when no_data_found
error_notify(ss_num);
end;
the question is that when i want to execute this procedure,how can I use the command?
I try to use the "execute get_dob('wang');"in the sql/plus,but the system give me wrong information.

Answer 1

Errors:
1. You left out the word PROCEDURE after CREATE OR REPLACE.
2. You used ss_number in one place and ss_num in two others. These must be the same name.
3. You left out the word THEN after WHEN NO_DATA_FOUND.
Possible errors:
1. Is birth_dae spelled correctly? Or, should it be birth_date?
2. Is error_notify a user-defined procedure?
Additional suggestions:
1. It is better to use table_name.column_name%TYPE instead of specifying NUMBER, VARCHAR2, DATE, etc. for your parameters. That way if the column data types are changed in the future, you don't have to change your code.
2. You will need to SET SERVEROUTPUT ON and use DBMS_OUTPUT.PUT_LINE to display the contents of the variable that holds the value of the out parameter.
3. Please see suggested code for creation of procedure and execution of procedure below. I have included one row of test data so that some output will be displayed. I commented out the exception section, in order to test it, since I don't have your error_notify procedure.
SQL> -- test data:
SQL> CREATE TABLE person
  2    (birth_dae   DATE,
  3     soc_sec_num NUMBER)
  4  /
Table created.
SQL> INSERT INTO person
  2  VALUES (SYSDATE, '123456789')
  3  /
1 row created.
SQL> SELECT * FROM person
  2  /
BIRTH_DAE SOC_SEC_NUM
06-DEC-02   123456789
SQL>
SQL>
SQL> -- create procedure:
SQL> CREATE OR REPLACE PROCEDURE get_dob
  2    (ss_number IN  person.soc_sec_num%TYPE,
  3     dob       OUT person.birth_dae%TYPE)
  4  AS
  5  BEGIN
  6    SELECT birth_dae
  7    INTO      dob
  8    FROM      person
  9    WHERE  soc_sec_num = ss_number;
10  -- EXCEPTION
11  --  WHEN NO_DATA_FOUND THEN
12  --    error_notify (ss_number);
13  END get_dob;
14  /
Procedure created.
SQL> SHOW ERRORS
No errors.
SQL>
SQL>
SQL> -- execute procedure:
SQL> SET SERVEROUTPUT ON
SQL> DECLARE
  2    v_dob DATE;
  3  BEGIN
  4    get_dob ('123456789', v_dob);
  5    DBMS_OUTPUT.PUT_LINE (v_dob);
  6  END;
  7  /
06-DEC-02
PL/SQL procedure successfully completed.