Changing the encoding attribute in xml output

Question

We are creating an xml file using:
vc_string_clob := dbms_xmlgen.getxml('select * from mytable');
then opening the file with UTL_FILE.FOPEN('dir','filename','W',31767)
then parsing through vc_string_clob and using UTL_FILE.PUT_LINE to write to the file.
This all works fine, expect the header of the XML file is <?xml version="1.0"?> and our users need it to be <?xml version="1.0" encoding="ISO-8859-1"?>
Is there a function within dbms_xmlgen that will allow me to change this?
I'm thinking I can use brute force to change it, but I'm sure there is a 'more correct' way to go about it.
Thank you,
Jill Jacomine

Answer 1

Hi Jill,
Welcome to the forum.
There are easier methods to output XML to a file, rather than using line-by-line UTL_FILE operations.
For example :
DECLARE
xml_result xmltype;
doc        dbms_xmldom.DOMDocument;
BEGIN
xml_result := dbms_xmlgen.getXMLType('SELECT * FROM scott.dept');
doc := dbms_xmldom.newDOMDocument(xml_result);
dbms_xmldom.writeToFile(doc, 'TEST_DIR/my_file.xml', 'ISO-8859-1');
dbms_xmldom.freeDocument(doc);
END;
/or,
DECLARE
xml_result xmltype;
xml_prolog clob := '<?xml version="1.0" encoding="ISO-8859-1"?>'||chr(10);
BEGIN
xml_result := dbms_xmlgen.getXMLType('SELECT * FROM scott.dept');
dbms_xslprocessor.clob2file(xml_prolog || xml_result.getClobVal(), 'TEST_DIR', 'my_file.xml');
END;
/Both will produce :
<?xml version="1.0" encoding="ISO-8859-1"?>
<ROWSET>
  <ROW>
    <DEPTNO>10</DEPTNO>
    <DNAME>ACCOUNTING</DNAME>
    <LOC>NEW YORK</LOC>
  </ROW>
  <ROW>
    <DEPTNO>20</DEPTNO>
    <DNAME>RESEARCH</DNAME>
    <LOC>DALLAS</LOC>
  </ROW>
  <ROW>
    <DEPTNO>30</DEPTNO>
    <DNAME>SALES</DNAME>
    <LOC>CHICAGO</LOC>
  </ROW>
  <ROW>
    <DEPTNO>40</DEPTNO>
    <DNAME>OPERATIONS</DNAME>
    <LOC>BOSTON</LOC>
  </ROW>
</ROWSET>Hope that helps.