Class CL_BCS Query for body part of mail

Question

HI,
I want to send the mail with out attachement using Class CL_BCS. Can any body help me on how to send the message body in the mail using CL_BCS class....
Thanx & Regards,
Sameer

Answer 1

Hi Sameer
I've been struggling with this class CL_BCS too for a while and I want to give my experience with that class. Following a code example which will submit a report to memory and send the report as an attachment by mail thru the SMTP interface.
*& Report  ZOBR_SEND_TRIP_SIM_BY_MAIL                                  *
*& This program does following:
*& 1. Submit a travel expense report to memory
*& 2. Read the travel expense report from memory
*& 3. Convert the travel expense report to HTML format
*& 4. Copy the travel expense report from format RAW(1000) to RAW(255)
*& 5. Send an email with body text and attachtments
REPORT  zobr_send_trip_sim_by_mail                                  .
DATA:
gi_abaplist     TYPE TABLE OF abaplist,
gi_html         TYPE          w3htmltab,
gs_html         LIKE LINE OF  gi_html,
gw_string       TYPE          string,
gw_length       TYPE          i,
gw_length_c     TYPE          so_obj_len,
gi_solix        TYPE          solix_tab,
gs_solix        LIKE LINE OF  gi_solix,
gi_soli         TYPE          soli_tab,
gs_soli         LIKE LINE OF  gi_soli,
go_send_request TYPE REF TO   cl_bcs,
go_document     TYPE REF TO   cl_document_bcs,
go_sender       TYPE REF TO   cl_sapuser_bcs,
go_recipient    TYPE REF TO   if_recipient_bcs,
go_exception    TYPE REF TO   cx_bcs.
* Submit report to memory
SUBMIT rprtef00 "USER sy-uname
  EXPORTING LIST TO MEMORY AND RETURN
  WITH pnppernr EQ '00001000'
  WITH pnptimra EQ 'X'
  WITH pnpxabkr EQ 'D2'
  WITH pnppabrp EQ '11'
  WITH pnppabrj EQ '2006'
  WITH s_reisen EQ '0002600221'
  WITH hinz_dru EQ space
  WITH hinz_weg EQ space
  WITH hinz_dyn EQ 'X'
  WITH allesdru EQ 'X'
  WITH reisepro EQ 'X'
  WITH reisetxt EQ 'X'
  WITH sw_antrg INCL 'X'
  WITH addinfo EQ 'X'
  WITH extperio EQ '000'
  WITH simulate EQ space
  WITH einkopf EQ space.
* Read report from memory
CALL FUNCTION 'LIST_FROM_MEMORY'
  TABLES
    listobject = gi_abaplist
  EXCEPTIONS
    not_found  = 1
    OTHERS     = 2.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Convert report to HTML format
CALL FUNCTION 'WWW_HTML_FROM_LISTOBJECT'
* EXPORTING
*   REPORT_NAME         =
*   TEMPLATE_NAME       = 'WEBREPORTING_REPORT'
  TABLES
    html                = gi_html
    listobject          = gi_abaplist.
LOOP AT gi_html INTO gs_html.
  CONCATENATE gw_string
              gs_html
         INTO gw_string.
ENDLOOP.
gw_length = STRLEN( gw_string ).
gw_length_c = gw_length.
* copy table from format raw(1000) to raw(255)
CALL FUNCTION 'TABLE_COMPRESS'
  TABLES
    in  = gi_abaplist
    out = gi_solix.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
TRY.
*   Create persistent send request
    go_send_request = cl_bcs=>create_persistent( ).
*   Create document (body text in text format)
    gs_soli = 'Trip is now settled, see attachment.'.
    APPEND gs_soli TO gi_soli.
    gs_soli = 'Reimbursement is paid out by your next salary.'.
    APPEND gs_soli TO gi_soli.
    go_document = cl_document_bcs=>create_document( i_type    = 'RAW'
                                                    i_text    = gi_soli
                                                    i_subject = 'Trip reimbursement' ).
*   Add attachment (ABAP list format)
    CALL METHOD go_document->add_attachment
      EXPORTING
        i_attachment_type    = 'ALI'
        i_attachment_subject = 'Expense report(ALI)'
        i_att_content_hex    = gi_solix.
*   Add attachment (HTML format)
    CALL METHOD go_document->add_attachment
      EXPORTING
        i_attachment_type    = 'HTM'
        i_attachment_subject = 'Expense report(HTM)'
        i_att_content_text   = gi_html.
*   Add note (Text format)
    CALL METHOD go_send_request->set_note( gi_soli ).
*   Add document to send request
    CALL METHOD go_send_request->set_document( go_document ).
*   Get sender object
    go_sender = cl_sapuser_bcs=>create( sy-uname ).
*   Add sender
    CALL METHOD go_send_request->set_sender
      EXPORTING
        i_sender = go_sender.
    go_recipient = cl_cam_address_bcs=>create_internet_address( '[email protected]' ).
*   Add recipient with its respective attributes to send request
    CALL METHOD go_send_request->add_recipient
      EXPORTING
        i_recipient  = go_recipient
        i_express    = ' '
        i_copy       = ' '
        i_blind_copy = ' '
        i_no_forward = ' '.
*   set send immediately flag
    go_send_request->set_send_immediately( 'X' ).
*   Send document
    CALL METHOD go_send_request->send( ).
    COMMIT WORK.
* Exception handling
  CATCH cx_bcs INTO go_exception.
    EXIT.
ENDTRY.
Notice that the only way to put a body text in the email is to call the method cl_document_bcs=>create_document with input of a type 'RAW'.
Be aware of the settings of the SMTP node in SAPConnect (transaction SCOT) because the seetings could cource an unwanted conversion of the email.
1. Doubbelclick on the TMTP node and a popup screen will show.
2. Click on the 'Set' button next to 'Internet' under 'Supported address type' and a       popup screen will show.
3. Set output format for SAP documents as 'SAPscript/Smart forms' = 'PDF', 'ABAP list' = 'PDF', 'RAW text' = 'TXT'.
This setting will convert 'SAPscript/Smartforms', 'ABAP list' to PDF format. If 'RAW text' = 'PDF' the body text wil be converted to 'PDF' format and change to an attachment and the body text will disappear.
Hope this is usefull for you and others.
Best regards
Ove Bryntesson
Applicon A/S