Class cl_bcs there's a way to set sender by dummy e-mail not by sap user ?

Question

Someone know if there's any possibilty to do this ?

Answer 1

Hi,
you can change the sender from SAP user to some other external mail id.......but that mail id must be a valid one.........
check the below code
DATA: send_request       TYPE REF TO cl_bcs,
      text               TYPE bcsy_text,
      document           TYPE REF TO cl_document_bcs,
      sender             TYPE REF TO cl_cam_address_bcs,
      recipient          TYPE REF TO cl_cam_address_bcs,
      bcs_exception      TYPE REF TO cx_bcs,
      sent_to_all        TYPE os_boolean.
TRY.
    send_request = cl_bcs=>create_persistent( ).
    APPEND 'Hi test' TO text.
    document = cl_document_bcs=>create_document(
                                          i_type    = 'RAW'
                                          i_text    = text
                                          i_length  = '7'
                                          i_subject = 'test' ).
    send_request->set_document( document ).
    sender    = cl_cam_address_bcs=>create_internet_address(
                                      'test at abcd.com' ).
    recipient = cl_cam_address_bcs=>create_internet_address(
                                      'test at abcd.com' ).
    send_request->set_sender( sender ).
    send_request->add_recipient(
                       EXPORTING
                          i_recipient = recipient
                          i_express   = 'X' ).
    send_request->send(
                    EXPORTING
                       i_with_error_screen = 'X'
                    RECEIVING
                       result              = sent_to_all ).
    COMMIT WORK.
  CATCH cx_bcs INTO bcs_exception.
    EXIT.
ENDTRY.
i hav replaced @ with 'at'
Cheers,
jose.