Collection-Inserting multiple rows in single shot within stored procedure

Question

Hello,
Below are the data for rows that I want to insert into CUSTOMER_PRODUCT table from a stored procedure.
Instead of making round trips twice to insert these two rows, I looking for a way to pass in the data for both those rows and then insert them from within the stored procedure in one shot.
The stored procedure will be invoked by Java and .NET.
Sample Data for CUSTOMERPRODUCT:_*
ROW 1:
CUSTOMER_ID : 1000
PRODUCT_TYPE : PROD123
IS_MEMERSHIP : Y
IS_EMAIL_SUBSCRIPTION: Y
ROW 2:
CUSTOMER_ID : 1001
PRODUCT_TYPE : PROD123
IS_MEMERSHIP : Y
IS_EMAIL_SUBSCRIPTION: Y
Question 1:
Which is the best way to do it?
Question 2:
Should collection be used? (or) is there any other approach that could be utilized?
Question 3:Can you please provide a sample?
Question 4:
Are there any performance concerns in passing collection and iterating it to fetch value to insert into CUSTOMER_PRODUCT table?
I'm running Oracle 10g.
Thanks!

Answer 1

user8291616 wrote:
>
Question 3:Can you please provide a sample?
A sample in PL/SQL. /* Exceptions are not handled...*/
SQL> create table test_customer
  2  (customer_id varchar2(10),PRODUCT_TYPE varchar2(10),
  3  IS_MEMERSHIP varchar2(1),IS_EMAIL_SUBSCRIPTION varchar2(1));
Table created.
SQL> create or replace package test_package is
  2     type cust_tab is table of test_customer%rowtype;
  3    procedure insert_customer(p_cust_dtls cust_tab);
  4  end;
  5  /
Package created.
SQL> create or replace package body test_package is
  2    procedure insert_customer(p_cust_dtls cust_tab) is
  3    begin
  4      forall i in 1..p_cust_dtls.count
  5          insert into test_customer
  6          (customer_id,PRODUCT_TYPE,IS_MEMERSHIP,IS_EMAIL_SUBSCRIPTION)
  7          values(p_cust_dtls(i).customer_id,p_cust_dtls(i).PRODUCT_TYPE,
  8                 p_cust_dtls(i).IS_MEMERSHIP,p_cust_dtls(i).IS_EMAIL_SUBSCRIPTION);
  9    end;
10  end;
11  /
Package body created.
--Calling the same in PL/SQL. You will do this part in JAVA..
SQL> declare
  2    lt_cust test_package.cust_tab := test_package.cust_tab();
  3  begin
  4    lt_cust.extend(2);
  5    lt_cust(1).customer_id := '1000';
  6    lt_cust(1).PRODUCT_TYPE := 'PROD123';
  7    lt_cust(1).IS_MEMERSHIP := 'Y';
  8    lt_cust(1).IS_EMAIL_SUBSCRIPTION := 'Y';
  9    lt_cust(2).customer_id := '1001';
10    lt_cust(2).PRODUCT_TYPE := 'PROD123';
11    lt_cust(2).IS_MEMERSHIP := 'Y';
12    lt_cust(2).IS_EMAIL_SUBSCRIPTION := 'Y';
13    test_package.insert_customer(lt_cust);
14    commit;
15  end;
16  /
PL/SQL procedure successfully completed.
SQL> select *
  2  from test_customer;
CUSTOMER_I PRODUCT_TY I I
1000       PROD123    Y Y
1001       PROD123    Y Y