Collection -- Nested tables

Question

Hi,
I am trying to use collections as nested tables from below mentioned procedure, but facing a problem of getting only last rows.
Any help would be appreciated.
+CREATE OR REPLACE PROCEDURE pr_collection
AS
TYPE type_num IS TABLE OF NUMBER;
t_num type_num;
TYPE type_char IS TABLE OF VARCHAR2 (20);
t_char type_char;
BEGIN
FOR i IN (SELECT eid, nm
FROM emp)
LOOP
t_num := type_num (i.eid);
t_char := type_char (i.nm);
DBMS_OUTPUT.put_line (i.eid || i.nm);
END LOOP;
DBMS_OUTPUT.put_line (t_num.COUNT);
DBMS_OUTPUT.put_line (t_num.FIRST);
DBMS_OUTPUT.put_line (t_num.LAST);
FORALL J IN T_NUM.FIRST.. T_NUM.LAST
INSERT INTO TEST
VALUES (t_num (J), t_char (J));
COMMIT;
END;
/+
Output :
1
1
1
Thanks in Advance,
Prashant

Answer 1

Hi,
It's normal, you get only the last element because of the following
LOOP
    t_num := type_num (i.eid);
    t_char := type_char (i.nm);
END LOOP;Each time you call the nested table constructor with the new element, so the previous elements are lost. The correct way of doing this is to call once the constructor before the LOOP and then call the EXTEND method inside the loop in order to make room available for each new element.
Therefore, something like this:
CREATE OR REPLACE PROCEDURE pr_collection AS
    TYPE type_num IS TABLE OF NUMBER;
    t_num type_num;
    t_num_idx PLS_INTEGER := 1;
    TYPE type_char IS TABLE OF VARCHAR2 (20);
    t_char type_char;
    t_char_idx PLS_INTEGER := 1;
BEGIN
    t_char := type_char();
    t_num := type_num();
    FOR i IN (SELECT eid, nm FROM emp) LOOP
        t_num.EXTEND;
        t_num(t_num_idx) := i.eid;
        t_num_idx := t_num_idx + 1;
        t_char.EXTEND;
        t_char(t_char_idx) := i.nm;
        t_char_idx := t_char_idx + 1;
        DBMS_OUTPUT.put_line (i.eid || i.nm);
    END LOOP;
    DBMS_OUTPUT.put_line (t_num.COUNT);
    DBMS_OUTPUT.put_line (t_num.FIRST);
    DBMS_OUTPUT.put_line (t_num.LAST);
    FORALL J IN T_NUM.FIRST.. T_NUM.LAST
        INSERT INTO TEST VALUES (t_num (J), t_char (J));
    COMMIT;
END;That being said, why do you add elements one by one, it is slow, why not using BULK COLLECT?
Regards,
Dariyoosh