Collections and counts

Question

Greetings!
I have a procedure in the following format:
PROCEDURE test as
type p1 is table of number;
tab_t1 p1;
cursor c1 is
(select ....... from table1);
begin
open c1;
loop
fetch c1 BULK COLLECT INTO tab_t1... limit 1000;
FORALL i in 1..tab_t1.count
insert into table2 values tab_t1(i);
commit;
exit when c1%notfound;
end loop;
msg := 'Count of records inserted ' || to_char(sql%rowcount);
test_util.write_to_log (handle, msg);
close c1;
commit;
end;
My question is where should the sql%rowcount be when we use collections (after closing the cursor or before end loop or ..), to capture count of all the records that have been inserted so far. Thank you,
Lakshmi
Message was edited by:
user6773

Answer 1

Ramana:
There is one major difference betqween your version and Adrian's accumulating SQL%ROWCOUNT for each of the INSERTS. Adrian uses a count of 0 in the collection to exit, and you are using cursr%NOTFOUND.
I created two procedures, one p based on your logic, and a second p1 based on Adrians. I also set the limit to something less than the number of records in the table, and not an even multiple of the number of records. so, the procedures are:
CREATE or replace PROCEDURE p AS
   TYPE array_tp IS TABLE OF t%ROWTYPE;
   l_array array_tp;
   CURSOR c IS
      SELECT * FROM t;
   l_cnt1 NUMBER := 0;
   l_cnt2 NUMBER := 0;
   l_cnt3 NUMBER := 0;
BEGIN
   OPEN c;
   LOOP
      FETCH c BULK COLLECT INTO l_array LIMIT 9;
      l_cnt1 := c%ROWCOUNT;
      FORALL i IN 1 .. l_array.COUNT
         INSERT INTO t1 VALUES l_array(i);
      EXIT WHEN c%NOTFOUND;
      l_cnt2 := l_cnt2 + SQL%rowcount;
   END LOOP;
   l_cnt3 := c%ROWCOUNT;
   CLOSE c;
   DBMS_OUTPUT.Put_Line('Cursor rowcount after fetch gives: '||l_cnt1);
   DBMS_OUTPUT.Put_Line('Accumulate sql rowcount after insert gives: '||l_cnt2);
   DBMS_OUTPUT.Put_Line('Cursor rowcount before close gives: '||l_cnt3);
END;
CREATE or replace PROCEDURE p1 AS
   TYPE array_tp IS TABLE OF t%ROWTYPE;
   l_array array_tp;
   CURSOR c IS
      SELECT * FROM t;
   l_cnt1 NUMBER :=0;
   l_cnt2 NUMBER :=0;
   l_cnt3 NUMBER :=0;
BEGIN
   OPEN c;
   LOOP
      FETCH c BULK COLLECT INTO l_array LIMIT 9;
      EXIT WHEN l_array.COUNT = 0;
      l_cnt1 := c%ROWCOUNT;
      FORALL i IN 1 .. l_array.COUNT
         INSERT INTO t1 VALUES l_array(i);
      l_cnt2 := l_cnt2 + SQL%rowcount;
   END LOOP;
   l_cnt3 := c%ROWCOUNT;
   CLOSE c;
   DBMS_OUTPUT.Put_Line('Cursor rowcount after fetch gives: '||l_cnt1);
   DBMS_OUTPUT.Put_Line('Accumulate sql rowcount after insert gives: '||l_cnt2);
   DBMS_OUTPUT.Put_Line('Cursor rowcount before close gives: '||l_cnt3);
END;Note that the line l_cnt3 := c%ROWCOUNT after the LOOP but before closing the cursor would be my preference as a way to get the count if you really needed it. Now running both I get:
SQL> SELECT COUNT(*) FROM t;
  COUNT(*)
        40
SQL> SELECT COUNT(*) FROM t1;
  COUNT(*)
         0
SQL> exec p
Cursor rowcount after fetch gives: 40
Accumulate sql rowcount after insert gives: 36
Cursor rowcount before close gives: 40
PL/SQL procedure successfully completed.
SQL> SELECT COUNT(*) FROM t1;
  COUNT(*)
        40
SQL> ROLLBACK;
SQL> exec p1;
Cursor rowcount after fetch gives: 40
Accumulate sql rowcount after insert gives: 40
Cursor rowcount before close gives: 40
PL/SQL procedure successfully completed.
SQL> SELECT COUNT(*) FROM t1;
  COUNT(*)
        40You version using SQL%ROWCOUNT misses the last partial set of rows because c%NOTFOUND is TRUE after fetching the last 4 rows from the table, so you exit the loop prior to accumulating. Moving the EXIT WHEN after assigning SQL%ROWCOUNT would give the correct results.
John