Column as header in a row

Question

Oracle 10g
Data in table:
type_code code_desc     group_id
577     TTW     1
325     RTT     1
562     URT     1
536     GEE     1
475     FDD     1
577     TTW     1
644     PST     2
I want the output in this manner. tried with 'connnect by prior'.
OUTPUT:
577     325     562     536 475
TTW      RTT     URT     GEE FDD
Basically column becomes the header.
Thanks.
Edited by: user545846 on May 13, 2009 8:51 PM

Answer 1

user545846 wrote:
suppose i just want the column as rows and the corresponding data below it.
header is not an issue.Can you clarify what you mean with some example data and expected output.
As for your original question you can dynamically assign column headings if you interface into the Oracle ODCI..
SQL> create or replace type NColPipe as object
  2  (
  3    l_parm varchar2(10),   -- The parameter given to the table function
  4    rows_requested number, -- The parameter given to the table function
  5    ret_type anytype,      -- The return type of the table function
  6    rows_returned number,  -- The number of rows currently returned by the table function
  7    static function ODCITableDescribe( rtype out anytype, p_parm in varchar2, p_rows_req in number := 1 )
  8    return number,
  9    static function ODCITablePrepare( sctx out NColPipe, ti in sys.ODCITabFuncInfo, p_parm in varchar2, p_rows_req in number := 1 )
10    return number,
11    static function ODCITableStart( sctx in out NColPipe, p_parm in varchar2, p_rows_req in number := 1 )
12    return number,
13    member function ODCITableFetch( self in out NColPipe, nrows in number, outset out anydataset )
14    return number,
15    member function ODCITableClose( self in NColPipe )
16    return number,
17    static function show( p_parm in varchar2, p_rows_req in number := 1 )
18    return anydataset pipelined using NColPipe
19  );
20  /
Type created.
SQL>
SQL> create or replace type body NColPipe as
  2    static function ODCITableDescribe( rtype out anytype, p_parm in varchar2, p_rows_req in number := 1 )
  3    return number
  4    is
  5      atyp anytype;
  6    begin
  7      anytype.begincreate( dbms_types.typecode_object, atyp );
  8      atyp.addattr( to_char(to_date(p_parm,'MONYYYY'),'MONYY')
  9                  , dbms_types.typecode_varchar2
10                  , null
11                  , null
12                  , 10
13                  , null
14                  , null
15                  );
16      atyp.endcreate;
17      anytype.begincreate( dbms_types.typecode_table, rtype );
18      rtype.SetInfo( null, null, null, null, null, atyp, dbms_types.typecode_object, 0 );
19      rtype.endcreate();
20      return odciconst.success;
21    exception
22      when others then
23        return odciconst.error;
24    end;
25  --
26    static function ODCITablePrepare( sctx out NColPipe, ti in sys.ODCITabFuncInfo, p_parm in varchar2, p_rows_req in number := 1 )
27    return number
28    is
29      elem_typ sys.anytype;
30      prec pls_integer;
31      scale pls_integer;
32      len pls_integer;
33      csid pls_integer;
34      csfrm pls_integer;
35      tc pls_integer;
36      aname varchar2(30);
37    begin
38      tc := ti.RetType.GetAttrElemInfo( 1, prec, scale, len, csid, csfrm, elem_typ, aname );
39      sctx := NColPipe( p_parm, p_rows_req, elem_typ, 0 );
40      return odciconst.success;
41    end;
42  --
43    static function ODCITableStart( sctx in out NColPipe, p_parm in varchar2, p_rows_req in number := 1 )
44    return number
45    is
46    begin
47      return odciconst.success;
48    end;
49  --
50    member function ODCITableFetch( self in out NColPipe, nrows in number, outset out anydataset )
51    return number
52    is
53    begin
54      anydataset.begincreate( dbms_types.typecode_object, self.ret_type, outset );
55      for i in self.rows_returned + 1 .. self.rows_requested
56      loop
57        outset.addinstance;
58        outset.piecewise();
59        outset.setvarchar2( self.l_parm );
60        self.rows_returned := self.rows_returned + 1;
61      end loop;
62      outset.endcreate;
63      return odciconst.success;
64    end;
65  --
66    member function ODCITableClose( self in NColPipe )
67    return number
68    is
69    begin
70      return odciconst.success;
71    end;
72  end;
73  /
Type body created.
SQL> select * from table( NColPipe.show( 'JAN2008' ) );
JAN08
JAN2008
SQL> select * from table( NColPipe.show( 'FEB2009' ) );
FEB09
FEB2009
SQL>