Concat vs ||

Question

Hi,
i am writing a some queries in SP which form dynamically. i do a lot of concatenation among strings and also numbers to prepare these queries.
can somebody tell me that which approach is better to use in terms of performance.
select concat(str,'popo') into str from dual ;
or
str:= str || 'popo';

Answer 1

Although I agree with the most of the comments here, there will be a performance diference between the two statements in your original post.
The first
SELECT concat(str, 'popo') INTO str FROM dual;requires a context switch from PL/SQL to the SQL engine, and will be slower than the direct assignment. As far as I can tell, there is no difference between a direct assignment using CONCAT and the || operator.
The following test shows that if you are going to do a lot of concatenation in a LOOP, then don't use SELECT INTO (good advice for almost anything in PL/SQL).
SQL> DECLARE
  2     l_str   VARCHAR2(15);
  3     l_start NUMBER;
  4     l_end   NUMBER;
  5     l_elap  NUMBER;
  6  BEGIN
  7     l_start := DBMS_UTILITY.Get_Time();
  8     FOR i IN 1 .. 10000 LOOP
  9        l_str := 'HELLO';
10        SELECT CONCAT(l_str, ' WORLD') INTO l_str
11        FROM dual;
12     END LOOP;
13     l_end := DBMS_UTILITY.Get_Time();
14     l_elap := l_end - l_start;
15     DBMS_OUTPUT.Put_Line('Select used '||l_elap||' centi seconds');
16
17     l_start := DBMS_UTILITY.Get_Time();
18     FOR i IN 1 .. 10000 LOOP
19        l_str := 'HELLO';
20        l_str := CONCAT(l_str, ' WORLD');
21     END LOOP;
22     l_end := DBMS_UTILITY.Get_Time();
23     l_elap := l_end - l_start;
24     DBMS_OUTPUT.Put_Line('Assign CONCAT '||l_elap||' centi seconds');
25
26     l_start := DBMS_UTILITY.Get_Time();
27     FOR i IN 1 .. 10000 LOOP
28        l_str := 'HELLO';
29        l_str := l_str || ' WORLD';
30     END LOOP;
31     l_end := DBMS_UTILITY.Get_Time();
32     l_elap := l_end - l_start;
33     DBMS_OUTPUT.Put_Line('Operator used '||l_elap||' centi seconds');
34  END;
35  /
Select used 96 centi seconds
Assign CONCAT 0 centi seconds
Operator used 1 centi seconds
PL/SQL procedure successfully completed.TTFN
John