Conditional colour formatting in apex_item select list

Question

Hello all,
I am having a select list in my tabular report created using apex_item.
What user want is the colour formatting of this select list according to the condition.
Say eg: A select list for departments, I want the departments with employees in different colour as compared to departments with no employees.
Please help.
Thanks
Tauceef

Answer 1

I've got a function in my package for this issue. Maybe it will gives you an idea how to solve this topic. The function is very similar to apex_item.select_list function, but there is a significant different. Displays values and returns values that are separated by two semicolons!
  FUNCTION get_select_list(p_idx NUMBER,
    p_value VARCHAR2 DEFAULT '',
    p_list_value VARCHAR2,
    p_attributes VARCHAR2 DEFAULT '',
    p_show_null VARCHAR2 DEFAULT '',
    p_null_value VARCHAR2 DEFAULT '',
    p_null_text VARCHAR2 DEFAULT '',
    p_item_id VARCHAR2 DEFAULT '') RETURN VARCHAR2 AS
    v_null VARCHAR2(4000);
    v_output VARCHAR2(4000);
    v_value VARCHAR2(4000);
    l_vc_fields htmldb_application_global.vc_arr2;
    l_vc_return_fields htmldb_application_global.vc_arr2;
  BEGIN
    l_vc_fields := HTMLDB_UTIL.string_to_table (p_list_value, ',');
    v_output := '<select name="f' || TRIM(TO_CHAR(p_idx, '09')) || '" ' || p_attributes;
    IF LENGTH(p_item_id) IS NOT NULL THEN
      v_output := v_output || ' id="' || p_item_id || '"';
    END IF;
    v_output := v_output || '>';
    v_null := '<option';
    IF LENGTH(p_null_value) IS NULL THEN
      v_null := v_null || ' value="%null%"';
    ELSE
      v_null := v_null || ' value="' || p_null_value || '"';
    END IF;
    v_null := v_null || '>';
    IF LENGTH(p_null_text) IS NULL THEN
      v_null := v_null || '%';
    ELSE
      v_null := v_null || p_null_text;
    END IF;
    v_null := v_null || '</option>';
    IF UPPER(p_show_null) != 'NO' THEN
      v_output := v_output || v_null;
    END IF;
    FOR i IN 1 .. l_vc_fields.COUNT LOOP
      l_vc_return_fields := HTMLDB_UTIL.string_to_table (l_vc_fields(i), ';;');
      v_output := v_output || '<option';
      IF l_vc_return_fields.COUNT = 2 THEN
        v_value := l_vc_return_fields(2);
      ELSE
        v_value := l_vc_return_fields(1);
      END IF;
      v_output := v_output || ' value="' || v_value || '"';
      IF v_value = p_value THEN
        v_output := v_output || ' selected="selected"';
      END IF;
      IF l_vc_return_fields.COUNT = 3 THEN
        v_output := v_output || ' ' || l_vc_return_fields(3);
      END IF;
      v_output := v_output || '>' || l_vc_return_fields(1) || '</option>';
    END LOOP;
    RETURN v_output || '</select>';
  END get_select_list;You can define three values for p_list_value instead of 2. The third value will be used as option attribute:
SELECT
my_package.get_select_list(
1,
'20',
'ACCOUNTING;;10,RESEARCH;;20,SALES;;30;;style="background-color: red;",OPERATIONS;;40'
) liste FROM dual;function returns
<select name="f01" >
<option value="10">ACCOUNTING</option>
<option value="20" selected="selected">RESEARCH</option>
<option value="SALES" style="background-color: red;">SALES</option>
<option value="40">OPERATIONS</option>
</select>The next step is just to create a function, which provide the string for p_list_value.