Create a file in fixed format through procedure

Question

Hi Gurus !!,
Your help is greatly appreciated .
I know to create a procedure  to genrate  the file in a .csv format 
But ,I have to create a procedure  to  generate a file in fixed format , So each field will have the length as per the length defied in the tables and with the page headers, etc
please help me here
beloW is the  table structure of statae .
state :
NAME               Not null     VARCHAR2 (40 Byte)      
STATE_CODE        Not null    VARCHAR2 (2 Byte)       
CONTINENTAL_US_FLAG     null     VARCHAR2 (1 Byte)     
sample data :
STATE_CODE
NAME
CONTINENTAL_US_FLAG
AI
ANGUILLA
AG
ANTIGUA AND BARBUDA
AW
ARUBA
N
BQ
BONAIRE,ST.EUSASIUS AND SABA
CW
CURACAO
Y
Data for the log and out files in the PROCESS_REFERENCE table
PROCESS_ID
PROCESS_NAME
FILE_IDENTIFIER
PATH_NAME
PROCESS_FILE_NAME
DATE_FORMAT_FOR_FILE_NAME
DEBUG_FLAG
369
FILE_STATE
LOG
/home/devtest/log/
<DATE>.FILE_STATE.LOG
YYYYMMDD
Y
340
FILE_STATE
OUT
/home/devtest/rpts/
<DATE>.FILE_STATE.OUT
YYYYMMDD
Y
This is the proc i created to generate .csv fiel which needs to be modidfied with fixed length formate as said above.
CREATE OR REPLACE PROCEDURE SAMPLE_FILE 
AS
   fLOG_FILE               UTL_FILE.FILE_TYPE;
   fRPT_FILE               UTL_FILE.FILE_TYPE;  
   vLOGFILE_PATH           PROD.PROCESS_REFERENCE.PATH_NAME%TYPE := NULL;
   vLOGFILE_NAME           PROD.PROCESS_REFERENCE.PROCESS_FILE_NAME%TYPE := NULL;
   nLOGFILE_PROCESS_ID     PROD.PROCESS_REFERENCE.PROCESS_ID%TYPE := NULL;
   vRPTFILE_PATH           PROD.PROCESS_REFERENCE.PATH_NAME%TYPE := NULL;
   vRPTFILE_NAME           PROD.PROCESS_REFERENCE.PROCESS_FILE_NAME%TYPE := NULL;
   nRPTFILE_PROCESS_ID     PROD.PROCESS_REFERENCE.PROCESS_ID%TYPE := NULL;
   vDEBUG_FLAG             PROD.PROCESS_REFERENCE.DEBUG_FLAG%TYPE := NULL;
   nWRITE_COUNT            NUMBER :=0;
   vSYS_TIME               VARCHAR2 ( 30 ):= NULL;
   bLOG                    BOOLEAN :=FALSE;
PROCEDURE PROC_LOG ( LINE_IN IN VARCHAR2 )
IS
BEGIN
    IF bLOG
      THEN
          vSYS_TIME :=TO_CHAR(SYSDATE, 'YYYYMMDD - HH24:MI:SS' );
          UTL_FILE.PUT_LINE ( fLOG_FILE, 'Process Started on ' ||vSys_Time || ' - ' || LINE_IN );
          UTL_FILE.FFLUSH ( fLOG_FILE );
           bLOG :=TRUE;
    END IF;
EXCEPTION
  WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('ERROR IN LOG  : ' || SUBSTR(SQLERRM,1,225));
         RAISE;
END PROC_LOG;
BEGIN
         SELECT  PROCESS_ID, PATH_NAME, REPLACE(PROCESS_FILE_NAME,'<DATE>',
           TO_CHAR(SYSDATE,DATE_FORMAT_FOR_FILE_NAME)) FILE_NAME, NVL(DEBUG_FLAG,'N') DEBUG_FLAG
          INTO  nLOGFILE_PROCESS_ID, vLOGFILE_PATH , vLOGFILE_NAME, vDEBUG_FLAG
          FROM  PROD.PROCESS_REFERENCE
          WHERE PROCESS_NAME = 'FILE_STATE'
          AND FILE_IDENTIFIER ='LOG' ;
           IF  vDEBUG_FLAG = 'Y' THEN
                BEGIN
                  fLOG_FILE :=UTL_FILE.FOPEN(vLOGFILE_PATH,vLOGFILE_NAME,'W',32767);
                   bLOG := TRUE;
                EXCEPTION
                  WHEN OTHERS THEN
                       bLOG := FALSE;
                   RAISE;
                END;
          END IF;
        BEGIN
                SELECT PROCESS_ID,PATH_NAME,
                     REPLACE(PROCESS_FILE_NAME,'<DATE>', TO_CHAR(SYSDATE,DATE_FORMAT_FOR_FILE_NAME)) FILE_NAME
                INTO nRPTFILE_PROCESS_ID, vRPTFILE_PATH, vRPTFILE_NAME
                FROM PROD.PROCESS_REFERENCE
                WHERE PROCESS_NAME = 'FILE_STATE'
                AND FILE_IDENTIFIER ='OUT' ;
                PROC_LOG ('Opening File : '||vRPTFILE_NAME);
                fRPT_FILE := UTL_FILE.FOPEN(vRPTFILE_PATH, vRPTFILE_NAME, 'W');
                UTL_FILE.PUT_LINE(fRPT_FILE,'STATE CODE' || ','
                                            || 'NAME' || ','                                       
                                            || 'CONTINENTAL_US_FLAG' );                         
        EXCEPTION
                WHEN NO_DATA_FOUND THEN
                    UTL_FILE.PUT_LINE(fLog_File,'ERROR in FILE OPEN : ' || SUBSTR(SQLERRM,1,1000));
                    RAISE;
        END;
         FOR CUR IN ( select state_code ,name, CONTINENTAL_US_FLAG from  state ,COUNTRY
                       WHERE ALPHA_CODE =STATE_CODE)
         LOOP
                UTL_FILE.PUT_LINE(fRPT_FILE ,CUR.state_code || ' ,'
                                  || '''' ||CUR.CONTINENTAL_US_FLAG||''','
                                  ||'"'||CUR.name||'"'); 
                                  nWRITE_COUNT :=nWRITE_COUNT+1;                                    
         END LOOP;
         IF UTL_FILE.is_open (fRPT_FILE)
           THEN
            UTL_FILE.fclose (fRPT_FILE);
         END IF;
         PROC_LOG('---- PROCESS COMPLETED ---> ');
         PROC_LOG('---TOTAL RECORDS WRITTEN ARE ---- : '|| nWRITE_COUNT );
         IF UTL_FILE.IS_OPEN (fLOG_FILE)
          THEN
            UTL_FILE.FCLOSE (fLOG_FILE);
            bLOG   := FALSE;
         END IF;
EXCEPTION
   WHEN OTHERS
      THEN
          IF UTL_FILE.is_open (fLOG_FILE) THEN
             PROC_LOG('ERROR IN MAIN !!' || SUBSTR(SQLERRM,1,250));
             UTL_FILE.fclose (fLOG_FILE);
                bLOG   := FALSE;
         ELSE
            DBMS_OUTPUT.PUT_LINE('ERROR IN MAIN !!' || SUBSTR(SQLERRM,1,250));
        END IF;
END SAMPLE_FILE  ;

Answer 1

Hi,
You can use RPAD to add spaces to the VARCHAR2 columns, like this:
UTL_FILE.PUT_LINE ( fRPT_FILE
                  , RPAD (CUR.state_code, 2) || ' ,'''  ||
                    CUR.CONTINENTAL_US_FLAG  || ''',"'  ||
                    RPAD (CUR.name, 40)      || '"'
Can the columns be NULL?  If so, you may need
UTL_FILE.PUT_LINE ( fRPT_FILE
                  , RPAD (NVL (CUR.state_code, ' '), 2) || ' ,'''  ||
                    NVL (CUR.CONTINENTAL_US_FLAG, ' ')  || ''',"'  ||
                    RPAD (NVL (CUR.name, ' '), 40)      || '"'
since   RPAD (str, len)   returns NULL if str is NULL.
Lose those EXCEPTION sections.  All they are doing is making it harder to find and fix errors.