Create Insert comand joining variables

Question

Hi, I'm having a problem, I want to create a execute immediate with the following code
The variable v_values as the values that i want to insert in the table, but i need to add the ' in the beggining and in the end ','' because the value of the variable looks like this:
1','1','','10-11-2004
QRY_INS := ('INSERT INTO TABOWN.GFNT02PD_PGMNT VALUES(''' || v_values || ''', '''')');
EXECUTE IMMEDIATE QRY_INS;
when i execute the command the result fo the qry_ins variable is like this:
INSERT INTO TABOWN.GFNT02PD_PGMNT VALUES('1','1',,TO_DATE('10-11-2004', 'DD-MM-YYYY'),'
the problems is because the ') comes down one line and the value for the last column becames too long, i already tries the rtrim but it didn't work.
thanks

Answer 1

Yep, you don't need dynamic SQL here at all. You're trying to take a shortcut and what you've done is given yourself a massive headache because of single-quote issues, and given your database a headache because of all those literals you're trying to embed in an insert statement.
The right way to handle this is to parse the values into separate variables (or array elements) and supply them as part of a static insert statement.
Here's some code that parses a delimited string into a string array and then uses the values in a static insert statement.
sql>CREATE OR REPLACE package pkg_split
  2  is
  3    type string_array is table of varchar2(32) index by pls_integer;
  4 
  5    function f_string_table(p_list in varchar2) return string_array;
  6  end;
  7  /
Package created.
sql>CREATE OR REPLACE package body pkg_split
  2  is
  3 
  4    function f_string_table(
  5      p_list in varchar2)
  6      return string_array
  7    is
  8      v_string  varchar2(256) := p_list || ',';
  9      v_pos     pls_integer;
10      v_data    string_array;
11    begin
12      loop
13        v_pos := instr(v_string, ',');
14        exit when (nvl(v_pos, 0) = 0);
15        v_data(v_data.count + 1) := trim(substr(v_string, 1, v_pos - 1));
16        v_string := substr(v_string, v_pos + 1);
17      end loop;
18      return (v_data);
19    end f_string_table;
20   
21  end;
22  /
Package body created.
sql>declare
  2    v_list varchar2(256) := 'horse,pig,cow,dog';
  3    v_arr  pkg_split.string_array;
  4  begin
  5    v_arr := pkg_split.f_string_table(v_list);
  6    insert into t (a, b, c, d) values (v_arr(1), v_arr(2), v_arr(3), v_arr(4));
  7  end;
  8  /
PL/SQL procedure successfully completed.
sql>select * from t;
A        B        C        D
horse    pig      cow      dog
1 row selected.