Create new IMAP & SMTP account with AppleScript

Question

After reading a thread over here where some of you mentioned the problem creating a new mail account using AppleScript in fact there really seems to be a bug that doesn't allow to change authentication of a SMTP server to Password.
So I ended up going this way using PListbuddy. Of course this is no complete script and you have to adapt it to your needs. But in general "automatic" creation of new accounts works fine. We're using it to provide this to our customers as Apple Mail does not support automatic creation of mail accounts using autoconfig or autoresponder.xml.
set command1 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0 dict' ~/Library/Preferences/com.apple.mail.plist"
set command9 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:AccountName string " & theMail & "' ~/Library/Preferences/com.apple.mail.plist"
set command2 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:AccountType string SMTPAccount' ~/Library/Preferences/com.apple.mail.plist"
set command3 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:Hostname string " & servername & "' ~/Library/Preferences/com.apple.mail.plist"
set command4 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:SSLEnabled string YES' ~/Library/Preferences/com.apple.mail.plist"
set command5 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:ShouldUseAuthentication string YES' ~/Library/Preferences/com.apple.mail.plist"
set command6 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:Username string " & username & "' ~/Library/Preferences/com.apple.mail.plist"
set command7 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:uniqueId string " & myid & "' ~/Library/Preferences/com.apple.mail.plist"
set command8 to "/usr/libexec/PlistBuddy -c 'Add :DeliveryAccounts:0:AuthenticationScheme string PASSWORD' ~/Library/Preferences/com.apple.mail.plist"
do shell script command1
do shell script command2
do shell script command3
do shell script command4
do shell script command5
do shell script command6
do shell script command7
do shell script command8
do shell script command9
tell application "Mail"
          set newimapac to make new imap account with properties {name:theDescription, user name:theUsername, uses ssl:true, server name:servername, port:"993", full name:theName, email addresses:{theMail}}
          tell newimapac
                    set authentication to password
                    set user name to username
                    set password to thePassword
          end tell
          set mysmtp to smtp server (theDescription)
          tell mysmtp
                    set password to mypass
          end tell
          set smtp server of newimapac to mysmtp
end tell

Answer 1

The following works exactly right, so far as I can tell (note that I made a copy of the Mail.app plist and renamed it
com.apple.mail_copy.plist). what are you doing differently?
set theMail to ""
set servername to ""
set myid to ""
set username to ""
set accountRecord to {AccountName:theMail, AccountType:"SMTPAccount", Hostname:servername, SSLEnabled:"YES", ShouldUseAuthentication:"YES", uniqueId:myid, |Username|:username, AuthenticationScheme:"PASSWORD"}
tell application "System Events"
          set theMailPlist to property list file "~/Library/Preferences/com.apple.mail_copy.plist"
          tell theMailPlist
                    tell property list item "DeliveryAccounts"
                              set newAccountItem to make new property list item at beginning with properties {kind:record, value:accountRecord}
                              tell newAccountItem
                                          make new property list item with properties {kind:string, name:"Username", value:username}
                              end tell
                    end tell
          end tell
end tell
to find a particular item in a list or directory, you use code like the following:
tell application "System Events"
          set theMailPlist to property list file "~/Library/Preferences/com.apple.mail_copy.plist"
          tell theMailPlist
                    tell property list item "DeliveryAccounts"
                              get every property list item whose (value of property list item "Username") contains "chump"
                    end tell
          end tell
end tell