[Crystal Report 13.0.2000.0 & VB 2010] - Database connection from VB Code

Question

Hi,
i want establish a connection between report and MsAccess database using source code in VB .NET 2010 listed below:
Imports CrystalDecisions.CrystalReports.Engine
Imports CrystalDecisions.Shared
Public Class Form1
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim crtableLogoninfos As New TableLogOnInfos()
        Dim crtableLogoninfo As New TableLogOnInfo()
        Dim crConnectionInfo As New ConnectionInfo()
        Dim CrTables As Tables
        Dim CrTable As Table
        Dim crReportDocument As New CrystalReport()
        With crConnectionInfo
            .ServerName = "c:\db.mdb"
            .DatabaseName = "db.mdb"
            .UserID = ""
            .Password = ""
        End With
        CrTables = crReportDocument.Database.Tables
        For Each CrTable In CrTables
            crtableLogoninfo = CrTable.LogOnInfo
            crtableLogoninfo.ConnectionInfo = crConnectionInfo
            CrTable.ApplyLogOnInfo(crtableLogoninfo)
            CrTable.Location = crConnectionInfo.DatabaseName
        Next
        CrystalReportViewer1.ReportSource = crReportDocument
    End Sub
End Class
This code work fine but the database connection parameters prompt every time on runtime!
HELP ME!

Answer 1

Hello,
I used our sample Xtreme.mdb to test this and it works for me. I am using RAS to make the connection though.
Here's the code on how:
Public Function ChangeConnectionInfo() as ReportDocument
Dim boReportDocument as New ReportDocument
'**EDIT** Change the path and report name to the report you want to change.
boReportDocument.Load("c:\reports\yourreport.rpt", OpenReportMethod.OpenReportByTempCopy)
'Create a new Database Table to replace the reports current table.
Dim boTable As New CrystalDecisions.ReportAppServer.DataDefModel.Table
'boMainPropertyBag: These hold the attributes of the tables ConnectionInfo object
Dim boMainPropertyBag As New PropertyBag
'boInnerPropertyBag: These hold the attributes for the QE_LogonProperties
'In the main property bag (boMainPropertyBag)
Dim boInnerPropertyBag As New PropertyBag
'Set the attributes for the boInnerPropertyBag
boInnerPropertyBag.Add("Data Source", "C:\xtreme.mdb")
boInnerPropertyBag.Add("Database Type", "Access")
boInnerPropertyBag.Add("Locale Identifier", "1033")
boInnerPropertyBag.Add("OLE DB Services", "-6")
boInnerPropertyBag.Add("Provider", "Microsoft.Jet.OLEDB.4.0")
boInnerPropertyBag.Add("Use DSN Default Properties", "False")
'Set the attributes for the boMainPropertyBag
boMainPropertyBag.Add("Database DLL", "crdb_ado.dll")
boMainPropertyBag.Add("QE_DatabaseName", "")
boMainPropertyBag.Add("QE_DatabaseType", "OLE DB (ADO)")
'Add the QE_LogonProperties we set in the boInnerPropertyBag Object
boMainPropertyBag.Add("QE_LogonProperties", boInnerPropertyBag)
boMainPropertyBag.Add("QE_ServerDescription", "C:\xtreme.mdb")
boMainPropertyBag.Add("QE_SQLDB", "True")
boMainPropertyBag.Add("SSO Enabled", "False")
'Create a new ConnectionInfo object
Dim boConnectionInfo As New CrystalDecisions.ReportAppServer.DataDefModel.ConnectionInfo
'Pass the database properties to a connection info object
boConnectionInfo.Attributes = boMainPropertyBag
'Set the connection kind
boConnectionInfo.Kind = CrConnectionInfoKindEnum.crConnectionInfoKindCRQE
'**EDIT** Set the User Name and Password if required.
boConnectionInfo.UserName = "UserName"
boConnectionInfo.Password = "Password"
'Pass the connection information to the table
boTable.ConnectionInfo = boConnectionInfo
'Get the Database Tables Collection for your report
Dim boTables As CrystalDecisions.ReportAppServer.DataDefModel.Tables = _
boReportDocument.ReportClientDocument.DatabaseController.Database.Tables
'For each table in the report:
' - Set the Table Name properties.
' - Set the table location in the report to use the new modified table
boTable.Name = "Credit"
boTable.QualifiedName = "Credit"
boTable.Alias = "Credit"
boReportDocument.ReportClientDocument.DatabaseController.SetTableLocation(boTables(0), boTable)
'Verify the database after adding substituting the new table.
'To ensure that the table updates properly when adding Command tables or Stored Procedures.
boReportDocument.VerifyDatabase()
Return boReportDocument
End Function
Thank you
Don