CSV conversion problem

Question

Hello,
I'm looking for help solving the following problem. For my research I'm using a program that crawls the web, looking for particular information. The input for this program are CSV files, in which each keyword is enclosed in ' '. In Numbers this isn't problematic if I set up the Text option for the cells. When I convert it to CSV however, the first ' disappears, so that the web program is fed with the wrong information and doesn't work.
Can anyone help me please?

Answer 1

In fact it seems that two problems strike.
(1) if the cell is not defined as text, the first single quote is dropped
(2) if cells are defined as text, the single straight quotes are replaced by smart curly single quotes which aren't what your other program requires.
This script takes care of that.
As I don't know if you need double quotes, I inserted a property allowing you to enclose values with double quotes or not.
--[SCRIPT clipboard2CSVfileWithQuotes]
Enregistrer le script en tant que Script, Application ou Progiciel :clipboard2CSVfileWithQuotes.xxx
déplacer le fichier créé dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
Copiez le bloc de cellules à exporter dans le Presse-papiers.
menu Scripts > Numbers > clipboard2CSVfileWithQuotes
Des apostrophes seront ajoutées si nécessaire.
Le script créera un fichier CSV dans lequel toutes les valeurs sont encadrées par des guillemets.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
+++++++
Save the script as a Script, an Application or an Application Bundle:clipboard2CSVfileWithQuotes.xxx
Move the newly created file into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
Coopy the range of cells to export into the clipboard
menu Scripts > Numbers > clipboard2CSVfileWithQuotes
Straight quotes will be inserted if required.
The script will create a CSV file in which every cell value is enclosed between double quotes.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
+++++++
Yvan KOENIG (Vallauris FRANCE)
21 juillet 2009
property curlyOpen : "‘" (* the 'smart' single opening quote used by Numbers *)
property curlyClose : "’" (* the 'smart' single closing quote used by Numbers *)
property doubleQuotesRequired : false
(* true = enclose every value with double quotes
false = doesn't enclose every value with double quotes *)
on run
try
set enTexte to the clipboard as text
set fName to (do shell script "date " & quote & "+_%Y%m%d-%H%M%S" & quote) & "." & "csv"
set p2d to path to desktop
tell application "System Events" to make new file at end of p2d with properties {name:fName}
set enListe to paragraphs of enTexte
repeat with r from 1 to count of enListe
set rowR to item r of enListe
set listeR to my decoupe(rowR, tab)
repeat with c from 1 to count of listeR
set itmRC to item c of listeR
if itmRC ends with curlyClose then set itmRC to (text 1 thru -2 of itmRC) & "'"
if itmRC starts with curlyOpen then set itmRC to "'" & (text 2 thru -1 of itmRC)
if (itmRC ends with "'") and itmRC does not start with "'" then set itmRC to ("'" & itmRC)
set item c of listeR to itmRC
end repeat
set item r of enListe to my recolle(listeR, tab)
end repeat
if doubleQuotesRequired then
set enTexte to my recolle(enListe, quote & return & quote)
set enTexte to my remplace(enTexte, tab, quote & "," & quote)
if enTexte does not start with quote then set enTexte to quote & enTexte
if enTexte does not end with quote then set enTexte to enTexte & quote
else
set enTexte to my recolle(enListe, return)
set enTexte to my remplace(enTexte, tab, ",")
end if
write enTexte to file ((p2d as text) & fName)
on error
if my parleAnglais() then
error "The clipboard doesn’t contain text data. Maybe you selected a Numbers sheet !"
else
error "Le presse-papiers ne contient pas de données texte. Vous avez peut-être copié une feuille de Numbers !"
end if
end try
end run
--=====
on decoupe(t, d)
local l
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to ""
return l
end decoupe
--=====
on recolle(l, d)
local t
set AppleScript's text item delimiters to d
set t to l as text
set AppleScript's text item delimiters to ""
return t
end recolle
--=====
replaces every occurences of d1 by d2 in the text t
on remplace(t, d1, d2)
local l
set AppleScript's text item delimiters to d1
set l to text items of t
set AppleScript's text item delimiters to d2
set t to l as text
set AppleScript's text item delimiters to ""
return t
end remplace
--=====
on parleAnglais()
local z
try
tell application "Numbers" to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]
Yvan KOENIG (from FRANCE mardi 21 juillet 2009 18:12:43)