Decimal and non-decimal in Smartforms

Question

Hi all,
I have a weird request on the form change. The change is to print the LFIMG value to 3 decimal point .000
For example, if the value is 2,000.010, then print 2,000.010
but if the value is 2,000.000 then print 2,000
Could someone guide me how handle this request?
Thanks in advance for the help.

Answer 1

Hi Wong,
I notice that this LFIMG is a quantity field. I had face that issue before, so this is my idea.
1/ Try to discuss with you Functional consultant to take the standard of SAP firstly. it always isn't a good way to do that.
2/ If your F tells you must do that:
- Check the decimal setting of user in SU01
- Write value base on this setting.
You can refer below code:
*&      Form  fg_decimal_notation
*  Get decimal notation of current user
*      -->P_USER     Current user
*      -->P_DECIMAL  decimal notation
FORM fg_decimal_notation USING p_user TYPE sy-uname
                              CHANGING  p_decimal.
  DATA:
        lv_dec_notation TYPE usr01-dcpfm.
  SELECT SINGLE dcpfm
    INTO lv_dec_notation
    FROM usr01
    WHERE bname = sy-uname.
  IF sy-subrc = 0.
    CASE lv_dec_notation.
      WHEN 'X'.
        p_decimal = '.'.
      WHEN OTHERS.
        p_decimal = ','.
    ENDCASE.
  ELSE.
*   If no record found we set the dec is ','
    p_decimal = ','.
  ENDIF.
ENDFORM.                    "fg_decimal_notation
*&      Form  f_convert_number
*  Convert number to text with or without decimal
*      -->PI_VALUE   Value
*      -->PI_DECIMAL decimal
*      -->PO_TEXT    Result
FORM f_convert_quantity_to_text USING pi_value
                                      pi_decimal
                                      pi_unit
                      CHANGING po_text TYPE text30.
  DATA:
        lv_text TYPE text30,
        lv_string TYPE string.
*-- write to external value
  TRY.
      WRITE pi_value TO lv_text UNIT pi_unit.
    CATCH cx_root.
  ENDTRY.
  CONDENSE lv_text.
* Put sign to front
  CALL FUNCTION 'CLOI_PUT_SIGN_IN_FRONT'
    CHANGING
      value = lv_text.
* Move to string
  MOVE lv_text TO lv_string.
*-- shift delete 0 in trail and decimal number
  FIND pi_decimal IN lv_text.
  IF sy-subrc = 0.
    SHIFT lv_string RIGHT DELETING TRAILING '0'.
    SHIFT lv_string RIGHT DELETING TRAILING pi_decimal.
  ENDIF.
*-- move result to data
  MOVE lv_string TO po_text.
ENDFORM.                    "f_convert_number
Hope that help,
Regards