Default document name

Question

Is there any way to change the default name of a document when you open a blank document. What I am trying to do is have my documents save in as a sequential number without Untitled in front of it. So the third document I save would be "0003" and the 50th would be "0050". Is there a way to do this without buying some sort of document management software? Maybe automator?

Answer 1

Here is a script for user template.
--[SCRIPT openAndNameWithAnumber]
Enregistrer le script en tant que Script, Application ou Progiciel : openAndNameWithAnumber.xxx
déplacer le fichier créé dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Pages:
Il vous faudra peut-être créer le dossier Pages et peut-être même le dossier Applications.
menu Scripts > Pages > openAndNameWithAnumber
crée un nouveau document à partir du modèle personnel prédéfini
et renomme le document avec un nouveau numéro.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
+++++++
Save the script as Script, Application or Application Bundle: openAndNameWithAnumber.xxx
Move the newly created file into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Pages:
Maybe you would have to create the folder Pages and even the folder Applications by yourself.
menu Scripts > Pages > openAndNameWithAnumber
will create a new document from the defined user template
and name it with a new number.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
--=====
Yvan KOENIG (Vallauris, FRANCE)
16 juin 2009
property theApp : "Pages"
property theExt : ""
property myTemplate : "ma_facture.template"
property fichierNum : "le_numéro.txt" (*
Adapter à vos besoins
Put your preferred title *)
--=====
on run
if theApp is "Pages" then
set theExt to "pages"
else if theApp is "Numbers" then
set theExt to "numbers"
else
if my parleAnglais() then
error "The application “" & theApp & "” is not supported !"
else
error "L’application « " & theApp & " » n’est pas gérée"
end if
end if
set {p2myTemplate, numero} to my prepare()
set numero to text -5 thru -1 of ("0000" & numero) (* pour numéro de 5 chiffres *)
set UNTITLED_loc to my getLocalizedFrameWorksName(theApp, "Untitled")
tell application theApp --"Numbers"
activate
try
close document UNTITLED_loc
end try
end tell -- to Numbers
tell application theApp --"Numbers"
activate
open p2myTemplate
set theDoc to numero & "." & theExt
set name of document 1 to theDoc
end tell
end run
--=====
on getLocalizedFrameWorksName(theApp, x)
local p2bndl
set p2bndl to (path to application support as text) & "iWork '09:Frameworks:SFApplication.framework:Versions:A:Resources:"
set x_loc to my getLocalizedName(theApp, x, p2bndl)
return x_loc
end getLocalizedFrameWorksName
--=====
on getLocalizedFunctionName(theApp, x)
local p2bndl
set p2bndl to (path to application support as text) & "iWork '09:Frameworks:SFTabular.framework:Versions:A:Resources:"
set x_loc to my getLocalizedName(theApp, x, p2bndl)
return x_loc
end getLocalizedFunctionName
--=====
on getLocalizedName(a, x, f)
tell application a to return localized string x from table "Localizable" in bundle file f
end getLocalizedName
--=====
on prepare()
local d1, d2, p2d, templatePathAsAlias, p2n, n
tell application theApp
set d1 to localized string "Templates" (* nom local du dossier "Modèles" *)
set d2 to localized string "My Templates" (* nom local du dossier "Mes Modèles" *)
end tell -- theApp
set p2d to (path to application support from user domain) as Unicode text
set templatePathAsAlias to p2d & "iWork:" & theApp & ":" & d1 & ":" & d2 & ":" & myTemplate & ":"
set p2n to templatePathAsAlias & fichierNum
try
set templatePathAsAlias to templatePathAsAlias as alias
on error
if my parleAnglais() then
error "The template “" & templatePathAsAlias & "” is unavailable! Please make sure the template file “" & myTemplate & "” is installed in Numbers' templates folder, then rerun this script."
else
error "Le modèle « " & templatePathAsAlias & " » est introuvable! Veuillez installer le fichier modèle « " & myTemplate & " » dans le dossier « Modèles:Mes modèles » de Numbers avant de relancer ce script."
end if
end try
tell application "System Events"
if not (exists file p2n) then
make new file at end of f with properties {name:fichierNum}
write "100" to file p2n (* mettez le numéro de départ de votre choix *)
end if -- not…
end tell -- System Events
set n to read file p2n
set n to ((n as integer) + 1) as text
write n to file p2n starting at 1
return {templatePathAsAlias, n}
end prepare
--=====
on parleAnglais()
local z
try
tell application "Numbers" to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]
Yvan KOENIG (from FRANCE mardi 16 juin 2009 19:53:51)