Deleting Master Data Requests in a Process Chain

Question

Hi All,
I need to delete and reload master data in a process chain.  I created an ABAP program that uses the function module "RSDMD_DEL_MASTER_DATA" to delete the master data.  I invoke this program from my process chain, and this is working well.  My master data is being deleted nicely.
Question, however.  I noticed that this does not delete the actual data request for that InfoObject.  If I manage that attribute, I still see the request appearing, eventhough I see no records when I select the option to maintain master data.
Can anyone tell me how I can delete the requests for master data, and how this can be done through a process chain?
Your assistance would be greatly appreciated.
Thank you,
John Stabile

Answer 1

Hi John,
I created a program giving the name of the master data object. Using this object, I found the request entries from rsiccont
Then I check these found entries in rsbkrequest, so as to find the status is successful.
rsbkrequest-tstate eq '2'.
rsbkrequest-ustate eq '2'
see the total code below.. you can copy paste the same
*TABLES
tables: rsiccont.
*SELECTION SCREEN
selection-screen begin of block a01 with frame title text-t01.
select-options : s_icube  for  rsiccont-icube obligatory.
parameter: p_num type i obligatory.
parameter: p_test as checkbox.
selection-screen end of block a01.
*Internal Table Definition
types: begin of t_rsiccont.
        include structure rsiccont.
types: recno like sy-tabix,
       end  of t_rsiccont.
data:  i_rsiccont type standard table of t_rsiccont with header line,
       i_rsiccont_ok type standard table of t_rsiccont with header line,
       i_rsbkrequest type standard table of rsbkrequest with header line.
*Work areas
data: wa_rsiccont  type t_rsiccont.
*Variables
data: lv_rnr   type rsiccont-rnr.
*AT SELECTION SCREEN
at selection-screen on s_icube.
  select single rnr
    into lv_rnr
    from rsiccont
    where icube in s_icube.
  if sy-subrc ne 0.
    message 'InfoCube not found' type 'E'.
  endif.
*START-OF-SELECTION
start-of-selection.
  select * up to p_num rows
    into table i_rsiccont
    from rsiccont
    where icube in s_icube.
  if sy-subrc eq 0.
    select *
      into table i_rsbkrequest
      from rsbkrequest
      for all entries in i_rsiccont
      where requid eq i_rsiccont-rnsidlast.
   if sy-subrc eq 0.
      loop at i_rsiccont.
        read table i_rsbkrequest with key requid = i_rsiccont-rnsidlast.
*check if status is = 2.
        check sy-subrc eq 0.
        check i_rsbkrequest-tstate eq '2'.
        check i_rsbkrequest-ustate eq '2'.
*actual mode -> delete the recrod!
        if p_test is initial.
          call function 'RSSM_PROCESS_REQUDEL_MDT'
            exporting
              i_dta     = i_rsiccont-icube
              i_request = i_rsiccont-rnr.
        endif.
        append i_rsiccont to i_rsiccont_ok.
      endloop.
    endif.
  endif.
*display list of all request numbers deleted!
  write: 'List of delete request numbers'.
  uline.
  skip.
  loop at i_rsiccont_ok.
    write: i_rsiccont_ok-rnr.
    skip.
  endloop.
=====================================================
You may need to correct the formatting
Edited by: Shailesh Khandarkar on Nov 11, 2009 7:42 AM
Edited by: Shailesh Khandarkar on Nov 11, 2009 7:46 AM