Difference between records in two data blocks

Question

Can you suggest me the best method to find difference (minus) between records in two similar data blocks.
Thanks!

Answer 1

What's your database version? Does this work? It can make the job a lot easier as you only have to loop through each block once.
-- create collection types
CREATE TYPE myobj AS object(col1 NUMBER, col2 NUMBER);
CREATE TYPE mytab AS TABLE OF myobj;
-- in the form:
DECLARE
  b1 mytab := mytab();
  b2 mytab := mytab();
BEGIN
  -- loop through blocks and populate collections
  b1.extend;
  b1(1) := myobj(1,1);
  b1.extend;
  b1(2) := myobj(2,1);
  b1.extend;
  b1(3) := myobj(3,5);
  b1.extend;
  b1(4) := myobj(4,2);
  b2.extend;
  b2(1) := myobj(1,1);
  b2.extend;
  b2(2) := myobj(2,2);
  b2.extend;
  b2(3) := myobj(3,5);
  -- find the difference (you might need to pass collections as parameters to a
  -- server-side function and do the query there)
  FOR rec IN (
    SELECT col1, col2 FROM TABLE(CAST(b1 AS mytab))
    MINUS
    SELECT col1, col2 FROM TABLE(CAST(b2 AS mytab))
  ) LOOP
    Dbms_Output.put_line(rec.col1||'-'||rec.col2);
  END LOOP;   
END;
/