Difference function

Question

Hi,
Is there any equivalent for SQL Server's difference function in Oracle. If not, is it possible to achieve the same ?
Thanks,
Sam

Answer 1

As far as I unterstand the specification you could use something like:
create or replace function my_difference (p_string1 IN VARCHAR2, p_string2 IN VARCHAR2) RETURN NUMBER
is
  v_str1 VARCHAR2(4);
  v_str2 VARCHAR2(4);
  v_count pls_integer := 0;
begin
   SELECT soundex(p_string1), soundex(p_string2)
   INTO   v_str1, v_str2
   FROM   dual;
   for i in 1..4 loop
     if (substr(v_str1, i,1) = substr(v_str2, i,1)) then
       v_count := v_count + 1;
     end if;
   end loop;
   RETURN v_count;
end my_difference;
SQL> -- Returns a DIFFERENCE value of 4, the least possible difference.
SQL> SELECT SOUNDEX('Green'),
  2    SOUNDEX('Greene'), MY_DIFFERENCE('Green','Greene')
  3  from dual;
SOUN SOUN MY_DIFFERENCE('GREEN','GREENE')
G650 G650                               4
SQL>
SQL> -- Returns a DIFFERENCE value of 0, the highest possible difference.
SQL> SELECT SOUNDEX('Blotchet-Halls'),
  2    SOUNDEX('Greene'), MY_DIFFERENCE('Blotchet-Halls', 'Greene')
  3  from dual;
SOUN SOUN MY_DIFFERENCE('BLOTCHET-HALLS','GREENE')
B432 G650                                        0
SQL>