Diffrence between STOP , RETURN , EXIT

Question

Hi all ,
Can some one plz tell me the diffrence between <b>STOP,RETURN , EXIT .</b>
It will be of great help if you explain <b>with a simple example</b> ..

Answer 1

<b>STOP</b>
Syntax
STOP.
Effect
The statement STOP is only to be used in executable programs and in the following event blocks:
AT SELECTION-SCREEN (without additions)
START-OF-SELECTION
GET
You leave these event blocks via STOP, and the runtime environment triggers the event END-OF-SELECTION.
Note
The statement STOP is forbidden in methods and, since Release 6.10, leads to an uncatchable exception during the processing of screens called with CALL SCREEN and in programs not called with SUBMIT.
Example
Ending the event blocks GET sbook after max postings have been issued, and branching to END-OF-SELECTION.
NODES: sflight, sbook.
DATA: bookings TYPE i,
      max TYPE i VALUE 100.
GET sflight.
  WRITE: / sflight-carrid, sflight-connid, sflight-fldate.
GET sbook.
  bookings = bookings + 1.
  WRITE: / sbook-bookid, sbook-customid.
  IF bookings = max.
    STOP.
  ENDIF.
END-OF-SELECTION.
  ULINE.
  WRITE: / 'First', bookings, 'bookings'.
<b>
RETURN</b>
Syntax
RETURN.
Effect
This statement immediately ends the current processing block. It can appear in any area of a processing block and ends this block regardless of which statement block or control structure the statement is in.
After leaving the processing block, the runtime environment, except for the reporting event blockSTART-OF-SELECTION, follows the schema in Leave processing blocks.
After you end the reporting event block START-OF-SELECTIONwith RETURN, the runtime environment does not trigger any further reporting events, rather, it calls the list processor directly to display the basic list.
Example
Leave the subprogram show_list with
RETURN, if one of the required formal parameters structure or data_tab is initial.
FORM show_list USING structure TYPE c
                     data_tab  TYPE ANY TABLE.
  DATA alv_list TYPE REF TO cl_gui_alv_grid.
  IF structure IS INITIAL OR
     data_tab  IS INITIAL.
    RETURN.
  ENDIF.
  CREATE OBJECT alv_list
         EXPORTING i_parent = cl_gui_container=>screen0.
  CALL METHOD alv_list->set_table_for_first_display
    EXPORTING i_structure_name = structure
    CHANGING  it_outtab        = data_tab.
  CALL SCREEN 100.
ENDFORM.
<b>EXIT</b> - loop
Syntax
EXIT.
Effect
If the EXIT statement is listed within a loop, it leaves the loop by ending the current loop process. Program execution is continued after the closing statement in the loop.
Note
Outside of a loop, the EXIT statement leaves the current processing block (see EXIT - Processing block). We recommend that you use EXIT within loops only.
Example
Leaving a loop with EXIT if the loop index sy-index is greater than a number limit.
DATA limit TYPE i VALUE 10.
DO.
  IF sy-index > limit.
    EXIT.
  ENDIF.
  WRITE / sy-index.
ENDDO.