Disable Adobe Reader XI Toolbar

Question

Hi,
I'm new to this type of programing, so sorry if i don't understand.
I did my research and noticed the only way to disable the Toolbar (when using a WebBrowser Control) is when calling the browser to MyWebBrowser.Navigate URL.
My problem is that I call the event once and it works. Call the same I select the WebBrowser to navigate to another document and works great.
Now, I click to go back to the first document and there, the Toolbar again.
This is done on MS Access (VBA), Here is my routine:
Private Sub cmdNavigate_Click()
On Error GoTo Err_Handler
If (Not IsNull(Me.document_name)) Then
    strDocumentPath = Trim(Me.document_path)
    strDocumentPath = strDocumentPath & Trim(Me.document_name) & "."
    strDocumentPath = strDocumentPath & Trim(Me.document_ext)
    If (FileExists(strDocumentPath)) Then
        Set ie = CreateObject("InternetExplorer.Application")
        With ie
            .navigate strDocumentPath & "#toolbar=0&navpanes=0"
             While (.Busy = True) Or (.ReadyState <> READYSTATE_COMPLETE): DoEvents: Wend
            .AddressBar = False
            .MenuBar = False
            .StatusBar = False
            .Toolbar = False
            .Visible = True
        End With
        Set ie = Nothing
    Else
        MsgBox "Error: File was not found", vbCritical, "Error"
    End If
End If
Err_Exit:
    Exit Sub
Err_Handler:
    DisplayUnexError Err.Number, Err.description
    Resume Err_Exit
End Sub
Any idea why is Adobe Reader not responding to the command passed with the URL after files has been open.
Thanks
SD

Answer 1

Found the issue.
I noticed while I was opening the IE instance, IE was leaving the instance in memory. So, I added the following subroutine to check if IE is already opened and with the current PDF.
Private Function FIExplorer(chkUrl As String) As Boolean
On Error Resume Next
FIExplorer = False
Set objShell = CreateObject("Shell.Application").Windows
If (objShell.count > 0) Then
    ieUrl = Trim(Replace(Replace(chkUrl, "%20", " "), "\", "/"))
    i = InStr(ieUrl, "//")
    If ((i > 0) And (i < 7)) Then
        ieUrl = Mid(ieUrl, i + 2)
    End If
    If (Right(ieUrl, 1) = "/") Then
        ieUrl = Left(ieUrl, Len(ieUrl) - 1)
    End If
    For Each objIe In objShell
        ieName = objIe.FullName
        If (InStr(ieName, "iexplore.exe")) Then
            wUrl = Trim(Replace(Replace(objIe.LocationURL, "%20", " "), "\", "/"))
            i = InStr(wUrl, "://")
            If ((i > 1) And (i < 7)) Then
                wUrl = Mid(wUrl, i + 3)
            End If
            If (Mid(wUrl, 1, 1) = "/") Then
                wUrl = Mid(wUrl, 2)
            End If
            If (Right(wUrl, 1) = "/") Then
                wUrl = Left(wUrl, Len(wUrl) - 1)
            End If
            If (StrComp(ieUrl, wUrl, 1) = 0) Then
                FIExplorer = True
                Exit For
            End If
        End If
    Next objIe
End If
Set objIe = Nothing
Set objShell = Nothing
End Function
Hope this helps someone with same issue.
SD