Display a photo via web dynpro (jpg files)

Question

Hi
I have photo's of employees which I would like to display via my Web dynpro (it is jpg files).  I was able to do it using an Interactive form element, but then I cannot resize the photo; it is to big.  I was hoping to display it via an Image element, but then I only see the icon, but not my photo.
Could someone please assist me in helping to display my photo better?
Regards
Debbie

Answer 1

Hi Debbie,
Below is the code to generate the URL using ICM cache
"l_image is the variable that has your image in XSTRING format.
DATA:gx_mimetype TYPE string VALUE 'JPG'.
****Create the cached response object that we will insert our content into
  DATA: cached_response TYPE REF TO if_http_response.
  CREATE OBJECT cached_response
    TYPE
      cl_http_response
    EXPORTING
      add_c_msg        = 1.
  TRY. " ignore, if compression can not be switched on
      CALL METHOD cached_response->set_compression
        EXPORTING
          OPTIONS = cached_response->co_compress_based_on_mime_type
        EXCEPTIONS
          OTHERS  = 1.
    CATCH cx_root.
  ENDTRY.
****set the data and the headers
  DATA: l_app_type TYPE string.
  DATA: l_xstring TYPE xstring,
        i_cache_timeout  TYPE i VALUE '300'.
  cached_response->set_data( l_image ).
  l_app_type = gx_mimetype.
  cached_response->set_header_field( name  = if_http_header_fields=>content_type
                                     value = l_app_type ).
****Set the Response Status
  cached_response->set_status( code = 200 reason = 'OK' ).
****Set the Cache Timeout - 60 seconds - we only need this in the cache
****long enough to build the page and allow the Image on the Client to request it.
  cached_response->server_cache_expire_rel( expires_rel = i_cache_timeout ).
  DATA: r_url TYPE string.
  DATA: i_path TYPE string VALUE '/sap/public',
        i_format TYPE string VALUE 'JPG'.
****Create a unique URL for the object
  DATA: guid TYPE guid_32.
  CALL FUNCTION 'GUID_CREATE'
    IMPORTING
      ev_guid_32 = guid.
  CONCATENATE i_path '/' guid '.' i_format INTO r_url.
****Cache the URL
  cl_http_server=>server_cache_upload( url      = r_url
                                       response = cached_response ).
" bind the generated url with the image uielement attribute
  DATA lo_el_context TYPE REF TO if_wd_context_element.
  DATA ls_context TYPE wd_this->element_context.
  DATA lv_url LIKE ls_context-url.
* get element via lead selection
  lo_el_context = wd_context->get_element(  ).
* set single attribute
  lo_el_context->set_attribute(
    EXPORTING
      name =  `URL`
      value = r_url ).
Hope this  helps!
Radhika