Display image in view

Question

Hi,
My requirement is to create a  web dynpro application where the first view contains all images stored in ECC along with one button (Display image). When the user clicks on the button Display image then another view should display the image on the screen.
I have created View1 with a table,which display the details of the table STXBITMAPs in it,when i select a row and press a button second view is displayed with a UI conatiner of type IMAGE.
Basiccaly when button on view1 is pressed, I get the value of the TDNAME field via lead_selection method and set this value to a global attribute, whch inturn is copied into second view and bonded to the SOURCE attribute of the UI element.
My problem is , that global attribute is being updated probley and value have been passed to second view..but Image is not being displayed on the screen.
Can anyone help me out in this.
Thanks in advance.
Pooja

Answer 1

You don't necessarily have to move your images from STXBITMAPS to the MIME repository.  You can display any image - not just those in the MIME repository, by placing the content in the ICM Cache.  This creates a temporary URL for any content.  So you just need to read the binary content of the image from STXBITMAPS into a XSTRING variable.  From there you can use this code sample to put the content in the cache and generate a URL:
****Create the cached response object that we will insert our content into
  data: cached_response type ref to if_http_response.
  create object cached_response
    type
      cl_http_response
    exporting
      add_c_msg        = 1.
*  cached_response->set_compression( options = cached_response->IF_HTTP_ENTITY~CO_COMPRESS_IN_ALL_CASES ).
try. " ignore, if compression can not be switched on
      call method cached_response->set_compression
        exporting
          options = cached_response->co_compress_based_on_mime_type
        exceptions
          others  = 1.
    catch cx_root.
  endtry.
****set the data and the headers
  data: l_app_type type string.
  data: l_xstring type xstring.
      cached_response->set_data( me->gx_content ).
      l_app_type = 'image/x-ms-bmp'.
  cached_response->set_header_field( name  = if_http_header_fields=>content_type
                                     value = l_app_type ).
****Set the Response Status
  cached_response->set_status( code = 200 reason = 'OK' ).
****Set the Cache Timeout - 60 seconds - we only need this in the cache
****long enough to build the page and allow the IFrame on the Client to request it.
  cached_response->server_cache_expire_rel( expires_rel = i_cache_timeout ).
****Create a unique URL for the object
  data: guid type guid_32.
  call function 'GUID_CREATE'
    importing
      ev_guid_32 = guid.
  concatenate i_path '/' guid '.' i_format into r_url.
****Cache the URL
  cl_http_server=>server_cache_upload( url      = r_url
                                       response = cached_response ).