Drawing Boxes in Script - main window

Question

hi,
In script, in main window <u>after table line item datas</u>, i want to draw a box in which i will place some text. On drawing box, it appears on top of that window which i dont want, since it should be placed after item details.
kapil.

Answer 1

I do not know this is still relevant for You or not but here is the solution what I did:
First of all I have to mention this requires SAP standard object modification. !!!
1.Start SE80 and get into STXC function group.
2.Select COP_RELATIVE_NUMBER subroutines and double click on that.
3.Click on Edit button and Get SSCR  Object number from SAP.
4.Change interface of the COP_RELATIVE_NUMBER subroutines extending it with TYPE parameters
5.Change the first if Statement.
6.Extend the Relative case section with a new WHEN '#'.
7. Cange All COP_RELATIVE_NUMBER calls with new input parameter in CO_BOX, In CO_POSITION, In CO_SIZE.
From now in Your SAP script You can call BOX statement like this:
BOX XPOS ‘#10’ TW YPOS ‘#10’ TW  …..
Will start drowing BOX from cursor current position plus 10 twip.
Numbers after the # sign are optional.
Solution works only with TW.
form co_box.
data: begin of bx,
        x    type i,
        y    type i,
        w    type i,
        h    type i,
        f    type i,
        i(3) type n,
      end of bx,
      next(10),
      xpos         type i,
      ypos         type i,
      is_relative like boolean.
  bx-x = ft-wpx.
  bx-y = ft-wpy.
  bx-w = ft-wpw.
  bx-h = ft-wph.
  while co-endline = false.
    perform cop_next using next 10.
    case next.
      when 'XPOS'.
*{   REPLACE        ED1K902054                                        1
*        perform cop_relative_number using is_relative xpos.
        perform cop_relative_number using is_relative xpos 'X'.
*}   REPLACE
        add xpos to bx-x.
      when 'YPOS'.
*{   REPLACE        ED1K902054                                        2
*        perform cop_relative_number using is_relative ypos.
        perform cop_relative_number using is_relative ypos 'Y'.
*}   REPLACE
        add ypos to bx-y.
      when 'WIDTH'.
        perform cop_number_value using bx-w.
      when 'HEIGHT'.
        perform cop_number_value using bx-h.
      when 'FRAME'.
        perform cop_number_value using bx-f.
      when 'INTENSITY'.
        perform cop_next using next 3.
        bx-i = next.
      when space. exit.
      when '.'.   exit.
      when others.
        perform cop_warning using subrc_param_unknown next.
    endcase.
  endwhile.
  perform cop_end.
  check co-error = false.
  perform pc_box using bx-x bx-y bx-w bx-h bx-f bx-i.
endform.
form co_position.
data: begin of pos,
        x type i,
        y type i,
      end of pos,
      next(10),
      relative like boolean,
      xpos     type i,
      ypos     type i.
  pos-x = ft-wpx.
  pos-y = ft-wpy.
  while co-endline = false.
    perform cop_next using next 10.
    case next.
      when 'XORIGIN'.
*{   REPLACE        ED1K902054                                        1
*        perform cop_relative_number using relative xpos.
        perform cop_relative_number using relative xpos 'X'.
*}   REPLACE
        if relative = true.
          add xpos to pos-x.
        else.
          pos-x = xpos.
        endif.
      when 'YORIGIN'.
*{   REPLACE        ED1K902054                                        2
*        perform cop_relative_number using relative ypos.
        perform cop_relative_number using relative ypos 'Y'.
*}   REPLACE
        if relative = true.
          add ypos to pos-y.
        else.
          pos-y = ypos.
        endif.
      when 'WINDOW'.
        pos-x = ft-tdwlefts.
        pos-y = ft-tdwtops.
      when 'PAGE'.
        pos-x = 0.
        pos-y = 0.
      when space. exit.
      when '.'.   exit.
      when others.
        perform cop_warning using subrc_param_unknown next.
    endcase.
  endwhile.
  perform cop_end.
  check co-error = false.
  ft-wpx = pos-x.
  ft-wpy = pos-y.
endform.
form co_size.
data: begin of dim,
        w type i,
        h type i,
      end of dim,
      next(10),
      relative     like boolean,
      width        type i,
      height       type i.
  dim-w = ft-wpw.
  dim-h = ft-wph.
  while co-endline = false.
    perform cop_next using next 10.
    case next.
      when 'WIDTH'.
*{   REPLACE        ED1K902054                                        1
*        perform cop_relative_number using relative width.
        perform cop_relative_number using relative width 'X'.
*}   REPLACE
        if relative = true.
          add width to dim-w.
        else.
          dim-w = width.
        endif.
      when 'HEIGHT'.
*{   REPLACE        ED1K902054                                        2
*        perform cop_relative_number using relative height.
        perform cop_relative_number using relative height 'Y'.
*}   REPLACE
        if relative = true.
          add height to dim-h.
        else.
          dim-h = height.
        endif.
      when 'WINDOW'.
        dim-w = ft-tdwwidths.
        dim-h = ft-tdwheights.
      when 'PAGE'.
        dim-w = form_header-tdpagwidth.
        dim-h = form_header-tdpagheigh.
      when space. exit.
      when '.'.   exit.
      when others.
        perform cop_warning using subrc_param_unknown next.
    endcase.
  endwhile.
  perform cop_end.
  check co-error = false.
  ft-wpw = dim-w.
  ft-wph = dim-h.
endform.
*{   REPLACE        ED1K902054                                        3
*form cop_relative_number using is_relative like boolean
*                               val         type i.
form cop_relative_number using is_relative like boolean
                               val         type i
                               type        type c.
*}   REPLACE
data: num type f,
      next(10).
  clear is_relative.
  perform cop_next using next 10.
*{   REPLACE        ED1K902054                                        1
*  if next(1) cn '+-.0123456789 '.
  if next(1) cn '#+-.0123456789 '.
*}   REPLACE
    perform cop_warning using subrc_param_unknown next.
    clear: is_relative, val.
    exit.
  else.
    if next+1(9) cn '.0123456789 '.
      perform cop_warning using subrc_param_unknown next.
      clear: is_relative, val.
      exit.
    else.
      case next(1).
        when '+'.
          is_relative = true.
          num = next+1(9).
        when '-'.
          is_relative = true.
          num = next+1(9).
          num = -1 * num.
*{   INSERT         ED1K902054                                        2
        when '#'.
          is_relative = true.
          num = next+1(9).
          case type.
            when 'X'.
              num = ( ft-line_width  - ft-rem_width ) + num.
            when 'Y'.
              num = ( ft-fill_height - ft-rem_height ) + num.
          endcase.
*}   INSERT
        when others.
          num = next.
      endcase.
    endif.
  endif.
  perform cop_num_val using num.
  val = num.
endform.