Dynamic structure of "string" data type. Please help.

Question

ABAPers,
I am calling cl_alv_table_create=>create_dynamic_table method to dynamically create a structure. The input structure definition is as follows:
data: xfc type lvc_s_fcat.
data: ifc type lvc_t_fcat.
* define Fld1
clear xfc.
xfc-fieldname = 'Fld1'.
xfc-datatype = 'string'.
append xfc to ifc.
* define Fld2
clear xfc.
xfc-fieldname = 'Fld2'.
xfc-datatype = 'string'.
append xfc to ifc.
Although the call to create_dynamic_table does not throw any exceptions, it appears Fld1 and Fld2 are not of "string" data type. I don't know of a way to see what type they are. However, they do have a length limit of 10 characters.
After some experimenting, it turns out that the method simply ignores "datatype" value if it doesn't understand it and creates the field with some default data type.
I would appreciate it if someone can show me how to create fields of "string" data type.
Thank you in advance for your help.
Pradeep

Answer 1

That's right, use STRG as the datatype.  Please see the example program.
report zrich_0003.
type-pools: slis.
data: new_table type ref to data,
      new_line  type ref to data.
data:  xfc type lvc_s_fcat,
       ifc type lvc_t_fcat.
field-symbols: <dyn_table> type standard table,
               <dyn_wa>,
               <fs>.
start-of-selection.
  clear xfc.
  xfc-fieldname = 'Field1' .
  xfc-datatype = 'STRG'.
  append xfc to ifc .
  clear xfc.
  xfc-fieldname = 'Field2' .
  xfc-datatype = 'STRG'.
  append xfc to ifc .
* Create dynamic internal table and assign to FS
  call method cl_alv_table_create=>create_dynamic_table
    exporting
      it_fieldcatalog = ifc
    importing
      ep_table        = new_table.
  assign new_table->* to <dyn_table>.
* Create dynamic work area and assign to FS
  create data new_line like line of <dyn_table>.
  assign new_line->* to <dyn_wa>.
  assign component 1 of structure <dyn_wa> to <fs>.
  <fs> = 'This is string 1'.
  assign component 2 of structure <dyn_wa> to <fs>.
  <fs> = 'This is string 2'.
  append <dyn_wa> to <dyn_table>.
* Write the values of internal table.
  loop at <dyn_table> into <dyn_wa>.
    do.
      assign component sy-index of structure <dyn_wa> to <fs>.
      if sy-subrc <> 0.
        exit.
      endif.
      write:/ <fs>.
    enddo.
  endloop.
REgards,
Rich Heilman