Empty Trash only on Connected Devices

Question

I know that Mac OS X keeps a separate trash for connected devices, like SD Cards or USB Thumbdrives, and that to empty that trash one normally empties the trash for the whole computer, is there a way to empty only the trash on an external device?

Answer 1

I know this is an old thread - but I thought I'd add a current, simple, and perfect solution user Jacques Rioux just posted on my thread on the same topic, as follows:
I use this script AppleScript, save it as Application :
on open these_volumes
    set t_id to user ID of (system info)
    repeat with i in these_volumes
        if (kind of (info for i without size)) is "Volume" then
            set tPath to (POSIX path of i) & ".Trashes/" & t_id
            do shell script "/bin/rm -Rf  " & (quoted form of tPath) & "/*"
        end if
    end repeat
end open
Drag/Drop Volume(s) on the application.
This script removes the items from your trash (user ID) folder on the volume.
if other users use the volume  this script will not delete the items from their  trash folder, otherwise the script would need an administrator password to do that.
If you want to eject the volume after emptying the trash, use this script.
on open these_volumes
    set t_id to user ID of (system info)
    set volToEject to {}
    repeat with i in these_volumes
        if (kind of (info for i without size)) is "Volume" then
            set tPath to (POSIX path of i) & ".Trashes/" & t_id
            do shell script "/bin/rm -Rf  " & (quoted form of tPath) & "/*"
            set end of volToEject to contents of i
        end if
    end repeat
    if volToEject is not {} then tell application "Finder" to eject volToEject
end open