Error in pdf report...pls give me a solution on this

Question

hi all....
i did a small pdf report program...checked successfully but the error in exception comes when executing after the selection screen(when write my report name)...
it says...the exception is:in the function get_print_parameters,the structure parameter "in_archieve_parameters" is typed in such a way that only actual parameters are allowed,which are compatible in unicode w.r.t the fragment view, however the specified one has an incompatible fragment view....
pls rectify...is it any other work i've to do in setting printers info????
expecting ur reply....

Answer 1

Hi sankar,
I use it in this way and i don't have any problems (ECC6).
DATA: BEGIN OF ITAB OCCURS 0,
         TEXT(72),
      END   OF ITAB.
DATA: PDF_FILESIZE TYPE I.
DATA: BIN_FILESIZE TYPE I.
DATA: PARAMS      LIKE PRI_PARAMS,
      VALID       TYPE C.
DATA: SPOOL_NR     LIKE TSP01-RQIDENT,
      SPOOL_NR_DEL LIKE TSP01_SP0R-RQID_CHAR.
DATA: BEGIN OF PDF_OUTPUT OCCURS 0.
        INCLUDE STRUCTURE TLINE.
DATA: END   OF PDF_OUTPUT.
DATA: DATEI TYPE STRING VALUE 'C:\TESTPDF.PDF'.
DATA: RC TYPE I.
START-OF-SELECTION.
  READ REPORT 'ZGRO_ITAB_PDF_SPOOL' INTO ITAB.
  CALL FUNCTION 'GET_PRINT_PARAMETERS'
    EXPORTING
      DESTINATION    = 'LOCA'
      LINE_SIZE      = 080
      IMMEDIATELY    = ' '
      NO_DIALOG      = 'X'
    IMPORTING
      OUT_PARAMETERS = PARAMS
      VALID          = VALID.
  CHECK VALID <> SPACE.
  NEW-PAGE PRINT ON PARAMETERS PARAMS NO DIALOG NO-TITLE NO-HEADING.
  LOOP AT ITAB.
    WRITE:/ ITAB.
  ENDLOOP.
  NEW-PAGE PRINT OFF.
  SPOOL_NR = SY-SPONO.
  CALL FUNCTION 'CONVERT_ABAPSPOOLJOB_2_PDF'
    EXPORTING
      SRC_SPOOLID   = SPOOL_NR
    IMPORTING
      PDF_BYTECOUNT = PDF_FILESIZE
    TABLES
      PDF           = PDF_OUTPUT.
  SPOOL_NR_DEL = SPOOL_NR.
  CALL FUNCTION 'RSPO_R_RDELETE_SPOOLREQ'
    EXPORTING
      SPOOLID = SPOOL_NR_DEL.
  BIN_FILESIZE = PDF_FILESIZE.
  CALL METHOD CL_GUI_FRONTEND_SERVICES=>GUI_DOWNLOAD
    EXPORTING
      BIN_FILESIZE = BIN_FILESIZE
      FILENAME     = DATEI
      FILETYPE     = 'BIN'
    CHANGING
      DATA_TAB     = PDF_OUTPUT[].
  CALL METHOD CL_GUI_FRONTEND_SERVICES=>EXECUTE
    EXPORTING
      DOCUMENT = DATEI.
END-OF-SELECTION.
Regards, Dieter