External table ORA-30657: operation not supported on external organized tab

Question

Hi all,
I try to create an external table and fill it with data out of my DB. Without the AS - Section everything is fine. The external table will be created but I don't get the data into it. Is there any possible way to write delimited data into a flat-file via external table or an other mechanism?
Regards Carsten
The full statement:
CREATE OR REPLACE DIRECTORY admin_dat_dir
AS 'E:\CDDTEST';
CREATE OR REPLACE DIRECTORY admin_log_dir
AS 'E:\CDDTEST';
CREATE OR REPLACE DIRECTORY admin_bad_dir
AS 'E:\CDDTEST';
DROP TABLE cdd_ext_vt;
-- create the external table
CREATE TABLE cdd_ext_vt
(vertrag_nr VARCHAR2(25),
kunden_name VARCHAR2(60)
ORGANIZATION EXTERNAL
TYPE ORACLE_LOADER
DEFAULT DIRECTORY admin_dat_dir
ACCESS PARAMETERS
records delimited by newline
badfile admin_bad_dir:'empxt%a_%p.bad'
logfile admin_log_dir:'empxt%a_%p.log'
fields terminated by ','
missing field values are null
( vetrag_nr, kunden_name
LOCATION ('cdd_ext_vt.dat')
REJECT LIMIT UNLIMITED
AS
select vt.vertrag,chr(34)||trim(person.name)||chr(34)
from vt,person
where vt.syskd = person.sysperson
and rownum < 11
;

Answer 1

Carsten,
You can use this to dump this procedure into csv file
create or replace function  dump_csv( p_query     in varchar2,
                                      p_separator in varchar2 default ',',
                                      p_dir       in varchar2 ,
                                      p_filename  in varchar2 )
return number
is
    l_output        utl_file.file_type;
    l_theCursor     integer default dbms_sql.open_cursor;
    l_columnValue   varchar2(4000);
    l_status        integer;
    l_colCnt        number default 0;
    l_separator     varchar2(10) default '';
    l_cnt           number default 0;
begin
    l_output := utl_file.fopen( p_dir, p_filename, 'w' );
    dbms_sql.parse(  l_theCursor,  p_query, dbms_sql.native );
    for i in 1 .. 255 loop
        begin
            dbms_sql.define_column( l_theCursor, i, l_columnValue, 4000 );
            l_colCnt := i;
        exception
            when others then
                if ( sqlcode = -1007 ) then exit;
                else
                    raise;
                end if;
        end;
    end loop;
    dbms_sql.define_column( l_theCursor, 1, l_columnValue, 4000 );
    l_status := dbms_sql.execute(l_theCursor);
    loop
        exit when ( dbms_sql.fetch_rows(l_theCursor) <= 0 );
        l_separator := '';
        for i in 1 .. l_colCnt loop
            dbms_sql.column_value( l_theCursor, i, l_columnValue );
            utl_file.put( l_output, l_separator || l_columnValue );
            l_separator := p_separator;
        end loop;
        utl_file.new_line( l_output );
        l_cnt := l_cnt+1;
    end loop;
    dbms_sql.close_cursor(l_theCursor);
    utl_file.fclose( l_output );
    return l_cnt;
end dump_csv;
REM Here is an example of using the above:
create or replace procedure test_dump_csv
as
    l_rows  number;
begin
    l_rows := dump_csv( 'select * from all_users where rownum < 25', ',', '/tmp', 'test.dat' );
end;
/HTH
SS