Extracting file name text

Question

I have written a script that automatically sends out via FTP application Transmit, any new file that enters into a hot folder
what I need now is..
a script that writes information on a textedit document
I need
•open up a textedit document
then prints
•the file name "theFile"
•time and date
•then saves the file on the desktop
THEN when another file is sent, the script adds that the next file done info to the text file thus creating a list of completed tasks

Answer 1

File Name, Time, and Date format -
on adding folder items to this_folder after receiving these_items
-- Create or open, and edit, 'Folder_Contents.txt' on the 'Desktop'.
set FILE_REF to open for access file (((path to desktop folder from user domain) as string) & "Folder_Contents.txt") with write permission
repeat with i in these_items
tell application "Finder" to set file_Name to ((displayed name of i) as string)
-- Writes the string at the end of 'Folder_Contents.txt'. (File Name, Time, and Date format)
write (file_Name & " " & (do shell script ("date +%H.%M.%S' '%d.%m.%Y")) & return) to FILE_REF starting at eof
end repeat
close access FILE_REF -- Close 'Folder_Contents.txt'.
end adding folder items to
... or. Date, Time, and File Name format -
on adding folder items to this_folder after receiving these_items
-- Create or open, and edit, 'Folder_Contents.txt' on the 'Desktop'.
set FILE_REF to open for access file (((path to desktop folder from user domain) as string) & "Folder_Contents.txt") with write permission
repeat with i in these_items
tell application "Finder" to set file_Name to ((displayed name of i) as string) -- Extract file name from files' full path.
-- Writes the string at the end of 'Folder_Contents.txt'. (Date, Time, and File Name format)
write ((do shell script ("date +%d.%m.%Y' '%H.%M.%S")) & " " & file_Name & return) to FILE_REF starting at eof
end repeat
close access FILE_REF -- Close 'Folder_Contents.txt'.
end adding folder items to
  Mac OS X (10.4.4)