Extracting package and procedure name in code

Question

In my exception processing I need to log the package and procedure name that got the exception. How do I obtain these two names without manually coding the names?
Thanks in anticipiation

Answer 1

A better option is to get the package name and the line numberA still better option is to utilize pl/scope (when you are in 11g (not sure about 10g)):
SQL> alter session set plscope_settings='identifiers:all'
Session altered.
SQL> set serverout on
SQL> create or replace package pkg
as
   procedure p1;
   procedure p2;
end pkg;
Package created.
SQL> create or replace package body pkg
as
   procedure get_scope (obj varchar2, line int)
   as
   begin
      for c in (select rpad (lpad (' ', 2 * (level - 1)) || name, 20, '.') || ' ' || rpad (type, 20) || rpad (usage, 20) identifier_usage_contexts
                from user_identifiers t
                where level != 1
                start with line = get_scope.line and object_name = obj
                connect by usage_id = prior usage_context_id)
      loop
         dbms_output.put_line (c.identifier_usage_contexts);
      end loop;
   end get_scope;
   procedure p1
   as
   begin
      null;
   end p1;
   procedure p2
   as
   begin
      get_scope ($$plsql_unit, $$plsql_line);
   end p2;
end pkg;
Package body created.
SQL> exec pkg.p2
  P2................ PROCEDURE           DEFINITION         
    PKG............. PACKAGE             DEFINITION         
    PKG............. PACKAGE             DECLARATION        
PL/SQL procedure successfully completed.