Finding highlighted text in Pages using Applescript

Question

Hi guys, I'm writing a script that will parse through a Pages document and retun me the indices of the first and last characters of each block of text which is highlighted with a given colour. I do have a script that works, the only problem is it runs very slowly.
Here's what I have at the moment:
tell application "Pages"
          tell front document
  --colour to test for in RGB (0 to 65535)
                    set testColour to {65535, 0, 65535}
                    set lastCharColour to missing value
                    set N to (count of characters)
                    set indexArray to {}
                    repeat with i from 1 to N
                              set thisCharColour to character background color of character i
  --add the character if it is highlighted
  --and the previous one wasn't
                              if thisCharColour is testColour and lastCharColour is not testColour then
                                        set end of indexArray to i
  --or add the previous one if this one is
  --not highlighted and the previous one was
                              else if thisCharColour is not testColour and lastCharColour is testColour then
                                        set end of indexArray to (i - 1)
                              end if
  --update the previous character's colour
                              set lastCharColour to thisCharColour
                    end repeat
  --if there are an odd number in the list,
  --the document must end with a highlight,
  --so we'll add the last character
                    if ((count of indexArray) mod 2) = 1 then
                              set end of indexArray to N
                    end if
                    get indexArray
          end tell
end tell
I'm parsing over every character in the document, and adding the index to a list if its background has changed colour either to or from the specified colour. It seems to be that the "get character background color of character i" call inside the loop is what's taking a long time. I have tried caching off a list of all the colours as a first step and then just comparing against an item in that list, but it's not significantly faster (in fact it might even be slower, I aborted it because it was taking too long).
I know in MS Word it is possible to do a find operation to find characters which are highlighted in a particular colour, so I was sondering if it was possible to do something similar in Pages, or can anybody think of a way to streamline my logic here?
Thanks,
Andy

Answer 1

However, I've just realised, my reason for getting the character indices was so as I could, in a subsequent step, get the characters themselves. I can modify your script to get the actual characters as well as the character offsets, and then where there's a break in the character offsets I can split the characters into substrings, as below:
set theBackgroundColor to {0, 65535, 0}
getCharIndex(theBackgroundColor)
on getCharIndex(bgColor)
          script o
                    property myList : {}
                    property charList : {}
          end script
          tell application "Pages" to tell front document
                    set o's myList to character offset of (characters whose its character background color is bgColor)
                    set o's charList to (characters whose its character background color is bgColor)
          end tell
          set tc to count o's myList
          if tc = 0 then return {}
          set i to 1
          set blockArray to {}
          set lastBlockEnd to 0
          repeat while i < tc
                    set N to item i of o's myList
                    repeat with J from (i + 1) to tc
                              set N to N + 1
                              set n1 to item J of o's myList
                              if N is not n1 then
                                        set end of blockArray to ((items i thru (J - 1) of o's charList) as text)
                                        set lastBlockEnd to (J - 1)
                                        exit repeat
                              end if
                    end repeat
                    set i to J
          end repeat
          set end of blockArray to ((items (lastBlockEnd + 1) thru tc of o's charList) as text)
  return blockArray
end getCharIndex
This has all your speed advantages, and still gets me the end result I'm after.