Finding image properties?

Question

I'm looking for a way in applescript to get the properties of an image in a rectangle specifically its color space. I want to be able to place info about the image in a text box.
I can get the the images
set theimages to all graphics of page 1
but I can't get find the code that digs deeper into the individual images/graphic
Can anybody help?

Answer 1

There are numerous ways to skin this cat using AppleScript… Here is an example that should show you what File/Image Data is available to MDLS & SIPS… You can use AppleScript's Image Events but it's pretty much SIPS in AppleScript classes… Both of these utilities will allow you to pull particular keys if you want or you can get the whole blob and parse in AppleScript… I guess you can sort the rest…
tell application "Adobe InDesign CS5"
          tell the active document
                    set myGraphics to all graphics
                    repeat with thisGraphic in myGraphics
                              set imgType to image type name of thisGraphic
                              if imgType = "JPEG" then
                                        set myFile to file path of item link of thisGraphic
  -- Convert HFS path to POSIX for the shell
                                        set myFile to quoted form of POSIX path of myFile
  -- Use Spotlight metadata
                                        set mdlsData to my mdlsImage(myFile)
  display dialog (mdlsData) giving up after 3
  -- Use Scriptable Image Processing System
                                        set sipsData to my sipsImage(myFile)
  display dialog (sipsData) giving up after 3
                              end if
                    end repeat
          end tell
end tell
on mdlsImage(path)
          return (do shell script "mdls " & path)
end mdlsImage
on sipsImage(path)
          return (do shell script "sips −-getProperty -g all " & path)
end sipsImage