Folder Action + Move Finder Items = Zero KB files

Question

I've got a folder action set that is supposed to run the Automator Action "Move Finder Items" on any file that gets placed in a specific folder (called "Folder A") and move it to "Folder B". I'm having an issue with larger files though.
As soon as I begin to transfer the file to "folder A" , the folder action runs and results in a "Zero KB" file in "Folder B".
Is there any way to keep the Folder Action from triggering until the file has completely copied to the folder with the Folder Action attached ("Folder A")?
A side note: I have this same folder action running on an iMac with Mac OS 10.6.3 and it works great . (This one was made with the newer version of Automator that shipped with 10.6 vs. Automator on 10.5 which made the action I am having trouble with)
Any input would be appreciated!

Answer 1

There is a check in *Snow Leopard* to see if the items have completed their copy/download, but Leopard does not do any checking - the script is triggered immediately. You can add your own delay with a *Run AppleScript* action, though, for example:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into an Automator 'Run AppleScript' action">
on run {input, parameters} -- wait for file copy to complete by testing the size of the containing folder
set theFolders to {} -- to handle items in different folders
set skippedItems to {}
repeat with anItem in the input -- get a list of unique folders
tell application "Finder"
get (container of anItem) as alias
if the result is not in theFolders then set the end of theFolders to the result
end tell
end repeat
repeat with aFolder in theFolders
set timeToWait to 30 -- time to wait for copy to complete
set interval to 2 -- test every interval seconds
set copied to false
tell application "Finder" to set currentSize to size of aFolder -- get initial size
repeat with timer from timeToWait to 1 by -interval -- check every interval seconds up to maximum time
delay interval
tell application "Finder" to set newSize to size of aFolder -- recheck size
if (newSize is equal to currentSize) then
set copied to true
exit repeat -- success
else -- update size
set currentSize to newSize
end if
end repeat
if not copied then set the end of skippedItems to quoted form of (aFolder as text) -- timed out
end repeat
showSkippedAlert for skippedItems
return input
end run
to showSkippedAlert for skippedItems
show an alert dialog for any items skipped, with the option to cancel the rest of the workflow
parameters - skippedItems [list]: the items skipped
returns nothing
if skippedItems is not {} then
set {alertText, theCount} to {"Error with waiting for items to copy", count skippedItems}
if theCount is greater than 1 then
set theMessage to (theCount as text) & space & " folders timed out"
else
set theMessage to "1 folder timed out"
end if
set theMessage to theMessage & " - copy of contents may be incomplete:"
set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
set {skippedItems, AppleScript's text item delimiters} to {skippedItems as text, tempTID}
if button returned of (display alert alertText message (theMessage & return & skippedItems) alternate button "Cancel" default button "OK") is "Cancel" then error number -128
end if
return
end showSkippedAlert
</pre>
The action will check the folder sizes, and when there is no change (or the wait times out) the input items are passed on.