Format of amounts in notification

Question

hi experts,
we have got a workflow on purchase requisition release, which is commun to several countries of the company.
A BSP was developed to have some informations about the purchase requisition in the mail sent to the approver.
It works fine except for the amounts output in the mail.
The batch user responsible of the job on program SWN_SELSEN uses comma as decimal representation, and so, amount are formatted by using this representation.
But some receivers (mainly english people) want to have the full dot as decimal representation.
As far i knwo, we can't have several jobs on SWN_SELSEN linked to differents batch users.
Is there any way to have the user decimal representation inside the mail?
Kind regards,
Christophe

Answer 1

hi,
thank you for your replies..
i have solved the problem as Mike told.
I made a class ZCL_UTILITIES with a method OUTPUT_NUMERIC_FOR_USER to format the output according to user decimal representation...
I called it from the BSP and it works fine.
Kind regards,
Christophe
parameters of the method:
Importing     I_USER     TYPE XUBNAME     User Name in User Master Record
Importing     I_NUMBER     TYPE ANY     Numeric field
Exporting     VALUE( O_STR )     TYPE STRING     Numeric formatted into string
types : begin of typ_separator,
    dcpfm type xudcpfm,
    thousand(1) type c,         "thousand separator
    decimal(1) type c,          "decimal separator
    end of typ_separator.
  data :
    la_current type typ_separator,
    la_output type typ_separator.
  data :
    l_out(100) type c,
    l_lg_out type i,
    l_lg type i,
    l_offset type i,
    l_type(1) type c,
    l_inside(1) type c.
  field-symbols <fs> type any.
* Check of the data type of I_NUMBER
  describe field i_number type l_type.
  case l_type.
    when 'F' or 'I' or 'P'.
      write i_number to l_out.
    when others.
      raise invalid_type.
  endcase.
* Read decimal representation for current user
  clear la_current.
  select single dcpfm from usr01 into la_current-dcpfm
    where bname = sy-uname.
  if sy-subrc ne 0.
    raise user_not_defined.
  endif.
* Definition of the separators for current user
  case la_current-dcpfm.
    when ' '.
      la_current-thousand = '.'.
      la_current-decimal  = ','.
    when 'X'.
      la_current-thousand = ','.
      la_current-decimal  = '.'.
    when 'Y'.
      la_current-thousand = ' '.
      la_current-decimal  = ','.
    when others.
  endcase.
* Read decimal representation for output user
  select single dcpfm from usr01 into la_output-dcpfm
    where bname = i_user.
  if sy-subrc ne 0.
    raise user_not_defined.
  endif.
* Definition of the separators for output user
  case la_output-dcpfm.
    when ' '.
      la_output-thousand = '.'.
      la_output-decimal  = ','.
    when 'X'.
      la_output-thousand = ','.
      la_output-decimal  = '.'.
    when 'Y'.
      la_output-thousand = ' '.
      la_output-decimal  = ','.
    when others.
  endcase.
  describe field l_out length l_lg in character mode.
  describe field i_number output-length l_lg_out.
  l_offset = l_lg - l_lg_out.
  assign l_out+l_offset(l_lg_out) to <fs>.
  if la_current-dcpfm ne la_output-dcpfm.
    describe field <fs> length l_lg in character mode.
    l_lg = l_lg - 1.
    check l_lg gt 0.
    do l_lg times.
      if l_inside is initial.       "to find the first number
        if <fs>+sy-index(1) ca '123456789'.
          l_inside = 'X'.
        endif.
        continue.
      endif.
      if <fs>+sy-index(1) eq la_current-thousand.  "replace thousand separator
        <fs>+sy-index(1) = la_output-thousand.
      elseif <fs>+sy-index(1) eq la_current-decimal. "replace decimal separator
        <fs>+sy-index(1) = la_output-decimal.
        exit.
      endif.
    enddo.
  endif.
  o_str = <fs>.